build.gradle

plugins {
	// Apply the java plugin to add support for Java
	id 'java'
	id 'groovy'
	id 'idea'
	id 'org.springframework.boot' version "2.0.6.RELEASE"
}

repositories {
	mavenCentral()
	//needed for locally installed jdbc4 from microsoft
	mavenLocal()
	maven { url "https://artifacts.elastic.co/maven" }
	maven { url "https://maven.elasticsearch.org/releases" }
}

version '1.3.1'
sourceCompatibility = JavaVersion.VERSION_11
targetCompatibility = JavaVersion.VERSION_11

sourceSets {
	main {
		java { srcDirs = [] }
		groovy {
			srcDirs = ['src/main/java', 'src/main/groovy']
		}
		resources {
			srcDir 'src/main/resources'
		}

	}
}


if (!hasProperty('mainClass')) {
	ext.mainClass = 'uk.ac.kcl.Main'
}

jar {
	baseName = 'cogstack'
}

idea {
	module {
		downloadSources = true
	}
}


dependencies {
	//logging
	compile group: 'org.slf4j', name:'slf4j-api', version:'1.7.25'
	compile group: 'ch.qos.logback', name: 'logback-classic', version: '1.2.3'
	compile group: 'org.apache.logging.log4j', name: 'log4j-api', version: '2.16.0'
	compile group: 'org.apache.logging.log4j', name: 'log4j-core', version: '2.16.0'

	// misc
	compile group: 'joda-time', name: 'joda-time', version: '2.10.1'
	compile group: 'com.google.code.gson', name: 'gson', version: '2.8.5'
	compile group: 'commons-io', name: 'commons-io', version: '2.6'


	// elasticsearch rest client and apache async client
	compile group: 'org.elasticsearch.client', name: 'elasticsearch-rest-client', version: '6.4.2'
	compile group: 'org.apache.httpcomponents', name: 'httpasyncclient', version: '4.1.4'

	// elasticsearch x-pack support
	compile 'org.elasticsearch.client:x-pack-transport:6.4.2'


	// dbms drivers
	compile group: 'org.hsqldb', name: 'hsqldb', version: '2.4.1'
	compile group: 'com.microsoft.sqlserver', name: 'mssql-jdbc', version: '9.4.0.jre11'
	compile group: 'net.sourceforge.jtds', name: 'jtds', version: '1.3.1'
	compile group: 'mysql', name: 'mysql-connector-java', version: '8.0.13'
	compile group: 'org.postgresql', name: 'postgresql', version: '42.2.5'

	// connection pool
	compile group: 'com.zaxxer', name: 'HikariCP', version: '5.0.0'


	// spring framework
	compile("org.springframework.boot:spring-boot-starter-batch:2.0.6.RELEASE")

	compile('org.springframework.batch:spring-batch-core:4.0.1.RELEASE')
	compile('org.springframework.batch:spring-batch-integration:4.0.1.RELEASE')

	compile('org.springframework:spring-web:5.1.2.RELEASE')
	compile('org.springframework:spring-core:5.1.2.RELEASE')
	compile('org.springframework:spring-test:5.1.2.RELEASE')
	compile('org.springframework:spring-jdbc:5.1.2.RELEASE')
	compile('org.springframework:spring-context:5.1.2.RELEASE')
	compile('org.springframework:spring-jms:5.1.2.RELEASE')

	compile('org.springframework.integration:spring-integration-core:5.0.9.RELEASE')
	compile('org.springframework.integration:spring-integration-jms:5.0.9.RELEASE')

	compile 'org.springframework.integration:spring-integration-java-dsl:1.2.3.RELEASE'

	// need to cover these in integration tests:
	compile 'org.apache.activemq:activemq-broker:5.15.7'
	compile 'org.apache.activemq:activemq-client:5.15.7'
	compile 'org.apache.activemq:activemq-spring:5.15.7'


	// nlp-related
	compile group: 'org.apache.commons', name: 'commons-collections4', version: '4.2'
	compile group: 'org.apache.commons', name: 'commons-lang3', version: '3.8.1'
	compile group: 'org.codehaus.groovy', name: 'groovy-all', version: '3.0.9'

	// gate framework
	// deprecated -- any nlp applications will be run as separate services
	compile group: 'uk.ac.gate', name: 'gate-core', version: '8.4.1'
	compile group: 'xml-apis', name: 'xml-apis', version: '1.4.01'


	// tika
	compile group: 'org.apache.tika', name: 'tika-core', version: '1.19.1'
	compile (group: 'org.apache.tika', name: 'tika-parsers', version: '1.19.1') {
		exclude group: 'commons-logging', module: 'commons-logging' //by both name and group
	}

	// for tika prior to 1.17 -- old J2EE support
	//compile group: 'javax.xml.bind', name: 'jaxb-api', version: '2.3.0'
	//compile group: 'com.sun.xml.bind', name: 'jaxb-core', version: '2.3.0'
	//compile group: 'com.sun.xml.bind', name: 'jaxb-impl', version: '2.3.0'
	//compile group: 'javax.activation', name: 'activation', version: '1.1.1'

	// tika parsers dependencies
	compile group: 'org.apache.pdfbox', name: 'jbig2-imageio', version: '3.0.2'
       compile group: 'com.github.jai-imageio', name: 'jai-imageio-jpeg2000', version: '1.3.0'
	compile group: 'org.xerial', name: 'sqlite-jdbc', version: '3.25.2'

	compile group: 'org.apache.ws.commons.util', name: 'ws-commons-util', version: '1.0.2'


	// tests
	// TODO: move from JUnit4 to JUnit5
	testCompile group: 'junit', name: 'junit', version: '4.12'
	testCompile group: 'org.mockito', name: 'mockito-core', version: '2.23.0'
	testCompile group: 'de.sven-jacobs', name: 'loremipsum', version: '1.0'

	// temporary dependencies for JUnit
	compile group: 'org.json', name: 'json', version: '20171018'
}

task wrapper(type: Wrapper) {
	gradleVersion = '7.3'
	distributionType 'all'
}

allprojects {
	gradle.projectsEvaluated {
		tasks.withType(JavaCompile) {
			options.compilerArgs << "-Xlint:unchecked"
		}
	}
}

if (!hasProperty('profile')) {
	ext.profile = 'dev'
}

apply from: "gradle/profile.${profile}.gradle"