-
Notifications
You must be signed in to change notification settings - Fork 7
/
base.gfx.sprite.bmx
1154 lines (924 loc) · 38.3 KB
/
base.gfx.sprite.bmx
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
Rem
====================================================================
Classes for Sprites and Spritecontainers
====================================================================
This class provides TSpritePack and TSprite, which are alternatives
to TImage as they use the principle of SpriteAtlases which decrease
the amount of drawcalls if sprites from the same base image
(spritepack) are drawn after another.
====================================================================
If not otherwise stated, the following code is available under the
following licence:
LICENCE: zlib/libpng
Copyright (C) 2002-now Ronny Otto, digidea.de
This software is provided 'as-is', without any express or
implied warranty. In no event will the authors be held liable
for any damages arising from the use of this software.
Permission is granted to anyone to use this software for any
purpose, including commercial applications, and to alter it
and redistribute it freely, subject to the following restrictions:
1. The origin of this software must not be misrepresented; you
must not claim that you wrote the original software. If you use
this software in a product, an acknowledgment in the product
documentation would be appreciated but is not required.
2. Altered source versions must be plainly marked as such, and
must not be misrepresented as being the original software.
3. This notice may not be removed or altered from any source
distribution.
====================================================================
EndRem
SuperStrict
Import BRL.Max2D
?not bmxng
Import Brl.Random
?bmxng
Import Random.Xoshiro
?
Import "base.util.event.bmx"
Import "base.util.vector.bmx"
Import "base.util.srectangle.bmx"
Import "base.gfx.imagehelper.bmx"
Import "base.util.graphicsmanagerbase.bmx"
Const ALIGN_LEFT:Float = 0
Const ALIGN_CENTER:Float = 0.5
Const ALIGN_RIGHT:Float = 1.0
Const ALIGN_TOP:Float = 0
Const ALIGN_BOTTOM:Float = 1.0
Global ALIGN_LEFT_TOP:TVec2D = New TVec2D
Global ALIGN_CENTER_TOP:TVec2D = New TVec2D.Init(ALIGN_CENTER, ALIGN_TOP)
Global ALIGN_RIGHT_TOP:TVec2D = New TVec2D.Init(ALIGN_RIGHT, ALIGN_TOP)
Global ALIGN_LEFT_CENTER:TVec2D = New TVec2D.Init(ALIGN_LEFT, ALIGN_CENTER)
Global ALIGN_CENTER_CENTER:TVec2D = New TVec2D.Init(ALIGN_CENTER, ALIGN_CENTER)
Global ALIGN_RIGHT_CENTER:TVec2D = New TVec2D.Init(ALIGN_RIGHT, ALIGN_CENTER)
Global ALIGN_LEFT_BOTTOM:TVec2D = New TVec2D.Init(ALIGN_LEFT, ALIGN_BOTTOM)
Global ALIGN_CENTER_BOTTOM:TVec2D = New TVec2D.Init(ALIGN_CENTER, ALIGN_BOTTOM)
Global ALIGN_RIGHT_BOTTOM:TVec2D = New TVec2D.Init(ALIGN_RIGHT, ALIGN_BOTTOM)
Global sALIGN_LEFT_TOP:SVec2F = New SVec2F
Global sALIGN_CENTER_TOP:SVec2F = New SVec2F(ALIGN_CENTER, ALIGN_TOP)
Global sALIGN_RIGHT_TOP:SVec2F = New SVec2F(ALIGN_RIGHT, ALIGN_TOP)
Global sALIGN_LEFT_CENTER:SVec2F = New SVec2F(ALIGN_LEFT, ALIGN_CENTER)
Global sALIGN_CENTER_CENTER:SVec2F = New SVec2F(ALIGN_CENTER, ALIGN_CENTER)
Global sALIGN_RIGHT_CENTER:SVec2F = New SVec2F(ALIGN_RIGHT, ALIGN_CENTER)
Global sALIGN_LEFT_BOTTOM:SVec2F = New SVec2F(ALIGN_LEFT, ALIGN_BOTTOM)
Global sALIGN_CENTER_BOTTOM:SVec2F = New SVec2F(ALIGN_CENTER, ALIGN_BOTTOM)
Global sALIGN_RIGHT_BOTTOM:SVec2F = New SVec2F(ALIGN_RIGHT, ALIGN_BOTTOM)
Type TSpritePack
Field image:TImage {nosave}
Field name:String
Field sprites:TSprite[]
Method Init:TSpritePack(image:TImage, name:String)
Self.image = image
Self.name = name
Return Self
End Method
Method GetImage:TImage()
Return image
End Method
'returns the sprite defined by "spriteName"
'if no sprite was found, the first in the pack is returned to avoid errors
Method GetSprite:TSprite(spriteName:String = "")
spriteName = Lower(spriteName)
For Local i:Int = 0 Until sprites.length
'skip missing or with wrong names
If Not sprites[i] Or Lower(sprites[i].name) <> spriteName Then Continue
Return sprites[i]
Next
Return sprites[0]
End Method
'returns the sprite from array position
'if no sprite was found, the first in the pack is returned to avoid errors
Method GetSpriteByPosition:TSprite(position:Int=0)
If Len(sprites) >= position Then Return sprites[0]
Return sprites[position]
End Method
'returns the sprite with a specified id
'if no sprite was found, the first in the pack is returned to avoid errors
Method GetSpriteByID:TSprite(id:Int=0)
For Local i:Int = 0 Until sprites.length
'skip missing
If Not sprites[i] Then Continue
If sprites[i].id <> id Then Return sprites[i]
Next
Return sprites[0]
End Method
Method HasSprite:Int(sprite:TSprite)
For Local i:Int = 0 Until sprites.length
'skip missing
If Not sprites[i] Then Continue
If Lower(sprites[i].name) = Lower(sprite.name) Then Return True
Next
Return False
End Method
Method AddSprite:Int(sprite:TSprite)
'skip if already added
If HasSprite(sprite) Then Return True
sprite.parent = Self
sprites :+ [sprite]
Return True
End Method
'draws the whole spritesheet
Method Render:Int(offsetX:Int, offsetY:Int)
DrawImage(GetImage(), 0 + offsetX, 0 + offsetY)
End Method
End Type
Type TNinePatchInformation
'center: size of the middle parts (width, height)
Field centerDimension:SVec2i
'border: size of TopLeft,TopRight,BottomLeft,BottomRight
Field borderDimension:SRect
'content: limits for displaying content
Field contentBorder:SRect
'the scale of "non-stretchable" borders - rest will scale
'automatically through bigger dimensions
Field borderDimensionScale:Float = 1.0
'subtract this amount of pixels on each side for markers
Const MARKER_WIDTH:Int = 1
Method Init:Int(area:TRectangle, pixmap:TPixmap)
'read markers in the image to get border and content sizes
borderDimension = ReadMarker(pixmap, 0)
contentBorder = ReadMarker(pixmap, 1)
If borderDimension.GetLeft() = 0 And borderDimension.GetRight() = 0 And borderDimension.GetTop() = 0 And borderDimension.GetBottom() = 0
If contentBorder.GetLeft() = 0 And contentBorder.GetRight() = 0 And contentBorder.GetTop() = 0 And contentBorder.GetBottom() = 0
Return False
EndIf
EndIf
'center has to consider the marker_width (content dimension marker)
centerDimension = New SVec2i(..
int(area.GetW() - (2* MARKER_WIDTH + borderDimension.GetLeft() + borderDimension.GetRight())), ..
int(area.GetH() - (2* MARKER_WIDTH + borderDimension.GetTop() + borderDimension.GetBottom())) ..
)
Return True
End Method
'read ninepatch markers out of the sprites image data
'mode = 0: sprite borders
'mode = 1: content borders
Method ReadMarker:SRect(pixmap:TPixmap, Mode:Int=0)
Local sourcepixel:Int
Local sourceW:Int = pixmap.width
Local sourceH:Int = pixmap.height
Local resL:Int, resT:Int, resB:Int, resR:Int
Local markerRow:Int=0, markerCol:Int=0, skipLines:Int=0
'do not check if there is no space for markers
If sourceW <= 0 Or sourceH <= 0 Then Return new SRect()
'content is defined at the last pixmap row/col
If Mode = 1
markerCol = sourceH - MARKER_WIDTH
markerRow = sourceW - MARKER_WIDTH
skipLines = 1
EndIf
' °= L ====== R = ° ROW ROW ROW ROW
' T T COL
' | | COL
' B B COL
' °= L ====== R = ° COL
Local minVal:Int = 0, maxVal:Int = 0
'find left border: from 1 to first non-transparent pixel in row 0
minVal = MARKER_WIDTH
maxVal = sourceW - MARKER_WIDTH
For Local i:Int = minVal Until maxVal
If ARGB_Alpha(ReadPixel(pixmap, i, markerCol)) > 0 Then resL = i - minVal;Exit
Next
'find right border: from left border the first non opaque pixel in row 0
minVal = MARKER_WIDTH + resL
'same maxVal as left border
For Local i:Int = minVal Until maxVal
If ARGB_Alpha(ReadPixel(pixmap, i, markerCol)) = 0 Then resR = maxVal - i;Exit
Next
'find top border: from 1 to first opaque pixel in col 0
minVal = MARKER_WIDTH
maxVal = sourceH - MARKER_WIDTH
For Local i:Int = minVal Until maxVal
If ARGB_Alpha(ReadPixel(pixmap, markerRow, i)) > 0 Then resT = i - minVal;Exit
Next
'find bottom border: from top border the first non opaque pixel in col 0
minVal = MARKER_WIDTH + resT
'same maxVal as top border
For Local i:Int = minVal To maxVal
If ARGB_Alpha(ReadPixel(pixmap, markerRow, i)) = 0 Then resB = maxVal - i;Exit
Next
Return SRect.CreateTLBR(resT, resL, resB, resR)
End Method
End Type
Type TSprite
'defines how many pixels have to get offset from a given position
Field offset:SRectI
'defines at which pixels of the area the content "starts"
'or how many pixels from the last row/col the content "ends"
Field padding:SRectI
Field area:TRectangle = New TRectangle.Init(0,0,0,0)
'the id is NOT globally unique but a value to make it selectable
'from a TSpritePack without knowing the name
Field id:Int = 0
Field name:String
Field frameW:Int
Field frameH:Int
Field frames:Int
'amount of rotation: 0=none, 90=90°clockwise, -90=90°anti-clockwise
Field rotated:Int = 0
Field parent:TSpritePack
Field _pix:TPixmap = Null
Field tileMode:Int = 0
Field ninePatch:TNinePatchInformation
Const BORDER_NONE:Int = 0
Const BORDER_LEFT:Int = 1
Const BORDER_RIGHT:Int = 2
Const BORDER_TOP:Int = 4
Const BORDER_BOTTOM:Int = 8
Const BORDER_ALL:Int = 1 | 2 | 4 | 8
Const TILEMODE_UNDEFINED:Int = 0
Const TILEMODE_STRETCHED:Int = 1
Const TILEMODE_TILED:Int = 2
Method Init:TSprite(spritepack:TSpritePack=Null, name:String, area:TRectangle, offset:TRectangle, frames:Int = 0, spriteDimension:TVec2D=Null, id:Int=0)
Self.name = name
Self.area = area.copy()
Self.id = id
parent = spritepack
If offset Then Self.offset = new SRectI(offset.GetIntX(), offset.GetIntY(), offset.GetIntW(), offset.GetIntH())
frameW = area.GetW()
frameH = area.GetH()
Self.frames = frames
If frames > 0
frameW = Ceil(area.GetW() / frames)
frameH = area.GetH()
EndIf
If spriteDimension And spriteDimension.x<>0 And spriteDimension.y<>0
frameW = spriteDimension.GetX()
frameH = spriteDimension.GetY()
EndIf
Return Self
End Method
Method Init:TSprite(spritepack:TSpritePack=Null, name:String, area:SRectI, offset:SRectI, frames:Int = 0, spriteDimension:TVec2D=Null, id:Int=0)
Self.name = name
Self.area = new TRectangle.Init(area.x, area.y, area.w, area.h)
Self.id = id
parent = spritepack
Self.offset = offset
frameW = area.w
frameH = area.h
Self.frames = frames
If frames > 0
frameW = Ceil(area.w / frames)
frameH = area.h
EndIf
If spriteDimension And spriteDimension.x<>0 And spriteDimension.y<>0
frameW = spriteDimension.GetX()
frameH = spriteDimension.GetY()
EndIf
Return Self
End Method
Method InitFromImage:TSprite(img:TImage, spriteName:String, frames:Int = 1)
If Not img
TLogger.Log("TSprite.InitFromImage()", "Image is null. Cannot create ~q"+spriteName+"~q.", LOG_ERROR)
Throw "TSprite.InitFromImage: Image is null. Cannot create ~q"+spriteName+"~q."
EndIf
'create new spritepack
Local spritepack:TSpritePack = New TSpritePack.init(img, spriteName+"_pack")
Init(spritepack, spriteName, New TRectangle.Init(0, 0, img.width, img.height), Null, frames)
spritepack.addSprite(Self)
Return Self
End Method
'create a sprite using a dataset containing the needed information
Method InitFromConfig:TSprite(data:TData)
If Not data Then Return Null
Local flags:Int = data.GetInt("flags", 0)
Local url:String = data.GetString("url", "")
Local name:String = data.GetString("name", "unknownSprite")
Local frames:Int = data.GetInt("frames", 0)
Local frameW:Int = data.GetInt("frameW", 0)
Local frameH:Int = data.GetInt("frameH", 0)
Local id:Int = data.GetInt("id", 0)
Local ninePatchEnabled:Int = data.GetBool("ninePatch", False)
Local definedTileMode:Int = data.GetInt("tileMode", TILEMODE_UNDEFINED)
Local parent:TSpritePack = TSpritePack(data.Get("parent", Null))
'create a new spritepack if none is assigned yet
If parent = Null
If flags & MASKEDIMAGE Then SetMaskColor(255,0,255)
Local img:TImage = LoadImage(url, flags)
If Not img
If Not img
TLogger.Log("TSprite.InitFromConfig()", "Image is null. Cannot create ~q"+name+"~q out of ~q"+url+"~q.", LOG_ERROR)
Throw "TSprite.InitFromConfig: Image is null. Cannot create ~q"+name+"~q out of ~q"+url+"~q."
EndIf
Throw "image null : "+name + " (url: "+url+" )"
Return Null
EndIf
'load img to find out celldimensions
If (frameW = 0 Or frameW = 0)
If frames > 0
frameW = ImageWidth(img) / frames
Else
frameW = ImageWidth(img)
EndIf
frameH = ImageHeight(img)
EndIf
parent = New TSpritePack.Init(img, name + "_pack")
If flags & MASKEDIMAGE Then SetMaskColor(0,0,0)
EndIf
'assign an offset rect if defined so
Local offsetLeft:Int = data.GetInt("offsetLeft", 0)
Local offsetRight:Int = data.GetInt("offsetRight", 0)
Local offsetTop:Int = data.GetInt("offsetTop", 0)
Local offsetBottom:Int = data.GetInt("offsetBottom", 0)
If offsetLeft <> 0 Or offsetRight <> 0 Or offsetTop <> 0 Or offsetBottom <> 0
offset = SRectI.CreateTLBR(offsetTop, offsetLeft, offsetBottom, offsetRight)
Else
offset = new SRectI()
EndIf
'define the area in the parental spritepack, if no dimension
'is defined, use the whole parental image
Local area:SRectI = New SRectI( data.GetInt("x", 0), ..
data.GetInt("y", 0), ..
data.GetInt("w", parent.GetImage().width), ..
data.GetInt("h", parent.GetImage().height) ..
)
'intialize sprite
Init(parent, name, area, offset, frames, New TVec2D.Init(frameW, frameH), id)
'rotation
rotated = data.GetInt("rotated", 0)
'padding
SetPadding( data.GetInt("paddingTop"), data.GetInt("paddingLeft"), ..
data.GetInt("paddingBottom"), data.GetInt("paddingRight") )
'recolor/colorize?
If data.GetInt("r",-1) >= 0 And data.GetInt("g",-1) >= 0 And data.GetInt("b",-1) >= 0
colorize( TColor.Create(data.GetInt("r"), data.GetInt("g"), data.GetInt("b")) )
EndIf
'enable nine patch if wanted
If ninePatchEnabled Then EnableNinePatch()
tileMode = definedTileMode
'add to parental spritepack
parent.addSprite(Self)
Return Self
End Method
'copies a given sprites image to the own area
Method SetImageContent(img:TImage, color:TColor)
Local tmppix:TPixmap = LockImage(parent.GetImage(), 0)
tmppix.Window(Int(area.GetX()), Int(area.GetY()), Int(area.GetW()), Int(area.GetH())).ClearPixels(0)
DrawImageOnImage(ColorizeImageCopy(img, color), tmppix, Int(area.GetX()), Int(area.GetY()))
UnlockImage(parent.GetImage(), 0)
End Method
Method GetName:String()
Return name
End Method
Method SetPadding:Int(padding:SRectI)
Self.padding = padding
End Method
Method SetPadding:Int(x:Int, y:Int, w:Int, h:Int)
Self.padding = new SRectI(x,y,w,h)
End Method
Method IsNinePatch:Int()
Return ninePatch <> Null
End Method
Method EnableNinePatch:Int()
if not ninePatch then ninePatch = new TNinePatchInformation()
if not _pix Then _pix = GetPixmap()
if not ninePatch.Init(area, _pix)
ninePatch = Null
Return False
Else
Return True
EndIf
End Method
Method GetNinePatchInformation:TNinePatchInformation()
Return ninePatch
End Method
'returns the image of this sprite (reference, no copy)
'if the frame is 0+, only this frame is returned
'if includeBorder is TRUE, then an potential ninePatchBorder will be
'included
Method GetImage:TImage(frame:Int=-1, includeBorder:Int=False)
'if a frame is requested, just return it (no need for "animated" check)
If frame >=0 Then Return GetFrameImage(frame)
Local DestPixmap:TPixmap
If includeBorder
DestPixmap = LockImage(parent.GetImage(), 0, False, True).Window(Int(area.GetX()), Int(area.GetY()), Int(area.GetW()), Int(area.GetH()))
Else
if IsNinePatch()
DestPixmap = LockImage(parent.GetImage(), 0, False, True).Window(Int(area.GetX()+ ninePatch.borderDimension.GetLeft()), Int(area.GetY() + ninePatch.borderDimension.GetTop()), Int(area.GetW() - ninePatch.borderDimension.GetLeft() - ninePatch.borderDimension.GetRight()), Int(area.GetH() - ninePatch.borderDimension.GetTop() - ninePatch.borderDimension.GetBottom()))
else
DestPixmap = LockImage(parent.GetImage(), 0, False, True).Window(Int(area.GetX()), Int(area.GetY()), Int(area.GetW()), Int(area.GetH()))
endif
EndIf
UnlockImage(parent.GetImage())
Return TImage.Load(DestPixmap, 0, 255, 0, 255)
End Method
Method GetFrameImage:TImage(frame:Int=0)
'give back whole image if no frames are configured
If frames <= 0 Then frame = 0
Local DestPixmap:TPixmap = LockImage(parent.GetImage(), 0, False, True).Window(Int(area.GetX() + frame * framew), Int(area.GetY()), framew, Int(area.GetH()))
Return TImage.Load(DestPixmap, 0, 255, 0, 255)
End Method
'return the pixmap of the sprite' image (reference, no copy)
Method GetPixmap:TPixmap(frame:Int=-1)
'give back whole image if no frames are configured
If frames <= 0 Then frame = -1
If Not parent.GetImage() Then Throw "TSprite.GetPixmap() failed: invalid parent.GetImage()"
Local DestPixmap:TPixmap
If frame >= 0
DestPixmap = LockImage(parent.GetImage(), 0, False, True).Window(Int(area.GetX() + frame * framew), Int(area.GetY()), framew, Int(area.GetH()))
Else
DestPixmap = LockImage(parent.GetImage(), 0, False, True).Window(Int(area.GetX()), Int(area.GetY()), Int(area.GetW()), Int(area.GetH()))
EndIf
Return DestPixmap
End Method
'creates a REAL copy (no reference) of an image
Method GetImageCopy:TImage(loadAnimated:Int = 1)
SetMaskColor(255,0,255)
If Self.frames >1 And loadAnimated
Return LoadAnimImage(GetPixmap().copy(), frameW, frameH, 0, frames, parent.GetImage().flags)
Else
Return LoadImage(GetPixmap().copy(), parent.GetImage().flags)
EndIf
End Method
Method GetColorizedImage:TImage(color:TColor, frame:Int=-1, colorizeMode:Int=0)
Return ColorizeImageCopy(GetImage(frame), color, 0,0,0, 1, -1, colorizeMode)
End Method
'removes the part of the sprite packs image occupied by the sprite
Method ClearImageData()
Local tmppix:TPixmap = LockImage(parent.GetImage(), 0)
tmppix.Window(Int(area.GetX()), Int(area.GetY()), Int(area.GetW()), Int(area.GetH())).ClearPixels(0)
End Method
Method GetMinWidth:Int(includeOffset:Int=True)
If ninePatch
Return ninePatch.borderDimension.GetLeft() + ninePatch.borderDimension.GetRight()
Else
Return GetWidth(includeOffset)
EndIf
End Method
Method GetWidth:Int(includeOffset:Int=True)
'substract 2 pixels (left and right) ?
Local ninePatchPixels:Int = 0
If ninePatch Then ninePatchPixels = 2
'todo: advanced calculation
If rotated = 90 Or rotated = -90
If includeOffset
Return area.GetH() - (offset.GetTop() + offset.GetBottom()) - (padding.GetTop() + padding.GetBottom()) - ninePatchPixels
Else
Return area.GetH() - (padding.GetTop() + padding.GetBottom()) - ninePatchPixels
EndIf
Else
If includeOffset
Return area.GetW() - (offset.GetLeft() + offset.GetRight()) - (padding.GetLeft() + padding.GetRight()) - ninePatchPixels
Else
Return area.GetW() - (padding.GetLeft() + padding.GetRight()) - ninePatchPixels
EndIf
EndIf
End Method
Method GetMinHeight:Int(includeOffset:Int=True)
If ninePatch
Return ninePatch.borderDimension.GetTop() + ninePatch.borderDimension.GetBottom()
Else
Return GetHeight(includeOffset)
EndIf
End Method
Method GetHeight:Int(includeOffset:Int=True)
'substract 2 pixles (left and right) ?
Local ninePatchPixels:Int = 0
If ninePatch Then ninePatchPixels = 2
'todo: advanced calculation
If rotated = 90 Or rotated = -90
If includeOffset
Return area.GetW() - (offset.GetLeft() + offset.GetRight()) - (padding.GetLeft() + padding.GetRight()) - ninePatchPixels
Else
Return area.GetW() - (padding.GetLeft() + padding.GetRight()) - ninePatchPixels
EndIf
Else
If includeOffset
Return area.GetH() - (offset.GetTop() + offset.GetBottom()) - (padding.GetTop() + padding.GetBottom()) - ninePatchPixels
Else
Return area.GetH() - (padding.GetTop() + padding.GetBottom()) - ninePatchPixels
EndIf
EndIf
End Method
Method GetFramePos:TVec2D(frame:Int=-1)
If frame < 0 Then Return New TVec2D.Init(0,0)
Local MaxFramesInCol:Int = Ceil(area.GetW() / framew)
Local framerow:Int = Ceil(frame / Max(1,MaxFramesInCol))
Local framecol:Int = frame - (framerow * MaxFramesInCol)
Return New TVec2D.Init(framecol * frameW, framerow * frameH)
End Method
'let spritePack colorize the sprite
Method Colorize(color:TColor)
'store backup
'(we clean image data before pasting colorized output)
Local newImg:TImage = ColorizeImageCopy(GetImage(), color)
'remove old image part
ClearImageData()
'draw now colorized image on the parent image
DrawImageOnImage(newImg, parent.GetImage(), Int(area.GetX()), Int(area.GetY()))
End Method
Method PixelIsOpaque:Int(x:Int, y:Int)
If x < 0 Or y < 0 Or x > frameW Or y > frameH
Print "out of bounds: "+x+", "+y
Return False
EndIf
If Not _pix
_pix = LockImage(GetImage())
'UnlockImage(parent.image) 'unlockimage does nothing in blitzmax (1.48)
EndIf
Return ARGB_Alpha(ReadPixel(_pix, x,y))
End Method
'draw the sprite onto a given image or pixmap
Method DrawOnImage(imageOrPixmap:Object, x:Int, y:Int, frame:Int = -1, alignment:TVec2D=Null, modifyColor:TColor=Null)
If frames <= 0 Then frame = -1
If Not alignment Then alignment = ALIGN_LEFT_TOP
If frame >= 0
x :- alignment.GetX() * framew
y :- alignment.GetY() * frameh
Else
x :- alignment.GetX() * area.GetW()
y :- alignment.GetY() * area.GetH()
EndIf
DrawImageOnImage(getPixmap(frame), imageOrPixmap, Int(x + offset.GetLeft()), Int(y + offset.GetTop()), modifyColor)
End Method
'draw the sprite onto a given image or pixmap
Method DrawOnImageSColor(imageOrPixmap:Object, x:Int, y:Int, frame:Int = -1, alignment:TVec2D=Null, modifyColor:SColor8, scaleX:Float=1.0, scaleY:Float=1.0)
If frames <= 0 Then frame = -1
If Not alignment Then alignment = ALIGN_LEFT_TOP
If frame >= 0
x :- alignment.GetX() * framew
y :- alignment.GetY() * frameh
Else
x :- alignment.GetX() * area.GetW()
y :- alignment.GetY() * area.GetH()
EndIf
DrawImageOnImageSColor(getPixmap(frame), imageOrPixmap, Int(x + offset.GetLeft()), Int(y + offset.GetTop()), modifyColor, 0, scaleX, scaleY)
End Method
'draw the sprite covering an area (if ninePatch is enabled, the
'stretching is only done on the center of the sprite)
Method DrawArea:Int(x:Float, y:Float, width:Float=-1, height:Float=-1, frame:Int=-1, skipBorders:Int = 0, clipRect:TRectangle = Null, forceTileMode:Int = 0)
If width=-1 Then width = area.GetW()
If height=-1 Then height = area.GetH()
If frames <= 0 Then frame = -1
'nothing to draw?
If width <= 0 Or height <= 0 Then Return False
'normal sprites draw their image stretched to area
If Not ninePatch
DrawResized(x, y, width, height, 0,0,0,0, frame, False, Null, tileMode)
Else
Local middleW:Int = area.GetW() - ninePatch.borderDimensionScale*(ninePatch.borderDimension.GetLeft()+ninePatch.borderDimension.GetRight())
Local middleH:Int = area.GetH() - ninePatch.borderDimensionScale*(ninePatch.borderDimension.GetTop()+ninePatch.borderDimension.GetBottom())
'minimal dimension has to be same or bigger than all 4 borders + 0.1* the stretch portion
'if borders are disabled, ignore them in minWidth-calculation
width = Max(width, Max(0.2*middleW, 2) + ninePatch.borderDimensionScale*((1-(skipBorders & BORDER_LEFT)>0)*ninePatch.borderDimension.GetLeft() + (1-(skipBorders & BORDER_RIGHT)>0)*ninePatch.borderDimension.GetRight()))
height = Max(height, Max(0.2*middleH, 2) + ninePatch.borderDimensionScale*((1-(skipBorders & BORDER_TOP)>0)*ninePatch.borderDimension.GetTop() + (1-(skipBorders & BORDER_BOTTOM)>0)*ninePatch.borderDimension.GetBottom()))
'dimensions of the stretch-parts (the middle elements)
'adjusted by a potential border scale
Local stretchDestW:Float = width - ninePatch.borderDimensionScale*(ninePatch.borderDimension.GetLeft()+ninePatch.borderDimension.GetRight())
Local stretchDestH:Float = height - ninePatch.borderDimensionScale*(ninePatch.borderDimension.GetTop()+ninePatch.borderDimension.GetBottom())
'border sizes
Local bsLeft:Int = ninePatch.borderDimension.GetLeft()
Local bsTop:Int = ninePatch.borderDimension.GetTop()
Local bsRight:Int = ninePatch.borderDimension.GetRight()
Local bsBottom:Int = ninePatch.borderDimension.GetBottom()
If skipBorders <> 0
'disable the borders by setting their size to 0
If skipBorders & BORDER_LEFT > 0
stretchDestW :+ bsLeft * ninePatch.borderDimensionScale
bsLeft = 0
EndIf
If skipBorders & BORDER_RIGHT > 0
stretchDestW :+ bsRight * ninePatch.borderDimensionScale
bsRight = 0
EndIf
If skipBorders & BORDER_TOP > 0
stretchDestH :+ bsTop * ninePatch.borderDimensionScale
bsTop = 0
EndIf
If skipBorders & BORDER_BOTTOM > 0
stretchDestH :+ bsBottom * ninePatch.borderDimensionScale
bsBottom = 0
EndIf
EndIf
'prepare render coordinates
Local targetX1:Int = x
Local targetX2:Int = targetX1 + bsLeft * ninePatch.borderDimensionScale
Local targetX3:Int = targetX2 + stretchDestW
Local targetY1:Int = y
Local targetY2:Int = targetY1 + bsTop * ninePatch.borderDimensionScale
Local targetY3:Int = targetY2 + stretchDestH
Local targetW1:Int = bsLeft * ninePatch.borderDimensionScale
Local targetW2:Int = stretchDestW
Local targetW3:Int = bsRight * ninePatch.borderDimensionScale
Local targetH1:Int = bsTop * ninePatch.borderDimensionScale
Local targetH2:Int = stretchDestH
Local targetH3:Int = bsBottom * ninePatch.borderDimensionScale
Local sourceX1:Int = NINEPatch.MARKER_WIDTH
Local sourceX2:Int = sourceX1 + ninePatch.borderDimension.GetLeft()
Local sourceX3:Int = sourceX2 + ninePatch.centerDimension.x
Local sourceY1:Int = NINEPatch.MARKER_WIDTH
Local sourceY2:Int = sourceY1 + ninePatch.borderDimension.GetTop()
Local sourceY3:Int = sourceY2 + ninePatch.centerDimension.y
Local vpx:Int, vpy:Int, vpw:Int, vph:Int
If clipRect
GetGraphicsManager().GetViewport(vpx, vpy, vpw, vph)
Local intersectingVP:SRect = clipRect.IntersectSRectXYWH(vpx, vpy, vpw, vph)
If intersectingVP.w > 0 and intersectingVP.h > 0
GetGraphicsManager().SetViewport(Int(intersectingVP.x), Int(intersectingVP.y), Int(intersectingVP.w), Int(intersectingVP.h))
EndIf
EndIf
'render
'top
If ninePatch.borderDimension.GetTop()
If ninePatch.borderDimension.GetLeft()
DrawResized( targetX1, targetY1, targetW1, targetH1, sourceX1, sourceY1, ninePatch.borderDimension.GetLeft(), ninePatch.borderDimension.GetTop(), frame, False, clipRect )
EndIf
DrawResized( targetX2, targetY1, targetW2, targetH1, sourceX2, sourceY1, ninePatch.centerDimension.x, ninePatch.borderDimension.GetTop(), frame, False, clipRect, tileMode )
If ninePatch.borderDimension.GetRight()
DrawResized( targetX3, targetY1, targetW3, targetH1, sourceX3, sourceY1, ninePatch.borderDimension.GetRight(), ninePatch.borderDimension.GetTop(), frame, False, clipRect )
EndIf
EndIf
'middle
If ninePatch.borderDimension.GetLeft()
DrawResized( targetX1 , targetY2, targetW1, targetH2, sourceX1, sourceY2, ninePatch.borderDimension.GetLeft(), ninePatch.centerDimension.y, frame, False, clipRect, tileMode )
EndIf
DrawResized( targetX2, targetY2, targetW2, targetH2, sourceX2, sourceY2, ninePatch.centerDimension.x, ninePatch.centerDimension.y, frame, False, clipRect, tileMode )
If ninePatch.borderDimension.GetRight()
DrawResized( targetX3, targetY2, targetW3, targetH2, sourceX3, sourceY2, ninePatch.borderDimension.GetRight(), ninePatch.centerDimension.y, frame, False, clipRect, tileMode )
EndIf
'bottom
If ninePatch.borderDimension.GetBottom()
If ninePatch.borderDimension.GetLeft()
DrawResized( targetX1, targetY3, targetW1, targetH3, sourceX1, sourceY3, ninePatch.borderDimension.GetLeft(), ninePatch.borderDimension.GetBottom(), frame, False, clipRect )
EndIf
DrawResized( targetX2, targetY3, targetW2, targetH3, sourceX2, sourceY3, ninePatch.centerDimension.x, ninePatch.borderDimension.GetBottom(), frame, False, clipRect, tileMode)
If ninePatch.borderDimension.GetRight()
DrawResized( targetX3, targetY3, targetW3, targetH3, sourceX3, sourceY3, ninePatch.borderDimension.GetRight(), ninePatch.borderDimension.GetBottom(), frame, False, clipRect )
EndIf
EndIf
'reset viewport if it was modified
If clipRect
GetGraphicsManager().SetViewport(vpX, vpY, vpW, vpH)
EndIf
EndIf
End Method
'draw the sprite resized/stretched
'source is a rectangle within sprite.area
Method DrawResized(tX:Float, tY:Float, tW:Float, tH:Float, sX:Float, sY:Float, sW:Float, sH:Float, frame:Int=-1, drawCompleteImage:Int=False, clipRect:TRectangle = Null, forceTileMode:Int = 0)
If frames <= 0 Then frame = -1
If drawCompleteImage Then frame = -1
'we got a frame request - try to find it
'calculate WHERE the frame is positioned in spritepack
If frame >= 0 And frameW > 0 And frameH > 0
Local MaxFramesInCol:Int = Floor(area.GetW() / framew)
Local frameInRow:Int = Floor(frame / MaxFramesInCol) '0based
Local frameInCol:Int = frame Mod MaxFramesInCol '0based
'move the source rect accordingly
sX = frameInCol*frameW
sY = frameinRow*frameH
'if no source dimension was given - use frame dimension
If sW <= 0 Then sW = frameW
If sH <= 0 Then sH = frameH
Else
'if no source dimension was given - use image dimension
If sW <= 0 Then sW = area.GetW()
If sH <= 0 Then sH = area.GetH()
EndIf
'resize source rect so it stays within the sprite's limits
sW = Min(area.GetW(), sW)
sH = Min(area.GetH(), sH)
'if no target dimension was given - use source dimension
If tW <= 0 Then tW = sW
If tH <= 0 Then tH = sH
'take care of offsets
If offset.x<>0 Or offset.y<>0 Or offset.w<>0 Or offset.h<>0
'top and left border also modify position to draw
'starting at the top border - so include that offset
If sY = 0
tY :+ -offset.GetTop()
tH :+ offset.GetTop()
sH :+ offset.GetTop()
Else
sY :+ offset.GetTop()
EndIf
If sX = 0
tX :+ -offset.GetLeft()
tW :+ offset.GetLeft()
sW :+ offset.GetLeft()
Else
sX :+ offset.GetLeft()
EndIf
'hitting bottom border - draw bottom offset
If (sY + sH) >= (area.GetH() - offset.GetBottom())
sH :+ offset.GetBottom()
tH :+ offset.GetBottom()
EndIf
'hitting right border - draw right offset
' if (sX + sW) >= (area.GetW() - offset.GetRight())
' sW :+ offset.GetRight()
' endif
EndIf
If clipRect
'check if render area is outside of clipping area
If Not clipRect.IntersectsXYWH(tX, tY, tW, tH) Then Return
'limit viewport to intersection of current VP and clipping area
Local vpx:Int, vpy:Int, vpw:Int, vph:Int
GetGraphicsManager().GetViewport(vpx, vpy, vpw, vph)
Local intersectingVP:SRect = clipRect.IntersectSRectXYWH(vpx, vpy, vpw, vph)
If intersectingVP.w > 0 and intersectingVP.h > 0
GetGraphicsManager().SetViewport(Int(intersectingVP.x), Int(intersectingVP.y), Int(intersectingVP.w), Int(intersectingVP.h))
If forceTileMode = TILEMODE_UNDEFINED Then forceTileMode = tileMode
If forceTileMode = TILEMODE_UNDEFINED Or forceTileMode = TILEMODE_STRETCHED
DrawSubImageRect(parent.GetImage(), Float(Floor(tX)), Float(Floor(tY)), Float(Ceil(tW)), Float(Ceil(tH)), Float(area.GetX() + sX), Float(area.GetY() + sY), sW, sH)
ElseIf forceTileMode = TILEMODE_TILED
Local startX:Int = Int(Floor(tX))
Local startY:Int = Int(Floor(tY))
Local w:Int = Int(Ceil(tW))
Local h:Int = Int(Ceil(tH))
Local x:Int = 0
While x <= w '- sourceCopy.GetIntW()
Local y:Int = 0
Local maxW:Int = Min(sW, w - x)
While y <= h - Int(sH)
Local maxH:Int = Min(sH, h - y)
DrawSubImageRect(parent.GetImage(), Float(startX + x), Float(startY + y), maxW, maxH, Float(area.GetX() + sX), Float(area.GetY() + sY), maxW, maxH)
y :+ Int(sH)
Wend
x :+ Int(sW)
Wend
EndIf
GetGraphicsManager().SetViewport(vpx, vpy, vpw, vph)
EndIf
Else
If tileMode = 0 'stretched
DrawSubImageRect(parent.GetImage(), Float(Floor(tX)), Float(Floor(tY)), Float(Ceil(tW)), Float(Ceil(tH)), Float(area.GetX() + sX), Float(area.GetY() + sY), sW, sH)
ElseIf tileMode = 1 'tiled
Local startX:Int = Int(Floor(tX))
Local startY:Int = Int(Floor(tY))
Local w:Int = Int(Ceil(tW))
Local h:Int = Int(Ceil(tH))
Local x:Int = 0
While x <= w '- int(sW)
Local y:Int = 0
Local maxW:Int = Min(sW, w - x)
While y <= h '- sourceCopy.GetIntH()
Local maxH:Int = Min(sH, h - y)
DrawSubImageRect(parent.GetImage(), Float(startX + x), Float(startY + y), maxW, maxH, Float(area.GetX() + sX), Float(area.GetY() + sY), maxW, maxH)
y :+ Int(sH)
Wend
x :+ Int(sW)
Wend
EndIf
'TODO: for "target = image" use DrawImageOnImage() and stretch
'via "ResizePixmap()"
EndIf
End Method
Method DrawClipped(x:Float, y:Float, w:Float, h:Float, offsetX:Float=0, offsetY:Float=0, frame:Int=-1)
DrawResized(x, y, 0#, 0#, offsetX, offsetY, w, h, frame)
End Method
Method DrawInArea(x:Float, y:Float, area:TRectangle = Null, frame:Int=-1)
Local vpx:Int, vpy:Int, vpw:Int, vph:Int
If area
GetGraphicsManager().GetViewport(vpx, vpy, vpw, vph)
Local intersectingVP:SRect = area.IntersectSRectXYWH(vpx, vpy, vpw, vph)
if intersectingVP.w < 0 or intersectingVP.h < 0
Return
EndIf
GetGraphicsManager().SetViewport(Int(intersectingVP.x), Int(intersectingVP.y), Int(intersectingVP.w), Int(intersectingVP.h))
EndIf
Draw(x, y)
'reset viewport if it was modified
If area
GetGraphicsManager().SetViewport(vpx, vpy, vpw, vph)
EndIf
End Method
Method TileDrawHorizontal(x:Float, y:Float, w:Float, alignment:TVec2D=Null, scale:Float=1.0, theframe:Int=-1)
If frames <= 0 Then theframe = -1
Local widthLeft:Float = w
Local currentX:Float = x
Local framePos:TVec2D = getFramePos(theframe)
Local alignX:Float = 0.0
Local alignY:Float = 0.0
If alignment
alignX = alignment.x
alignY = alignment.y
EndIf