-
Notifications
You must be signed in to change notification settings - Fork 71
/
gdi_plus_plus.ahk
996 lines (895 loc) · 41.7 KB
/
gdi_plus_plus.ahk
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
class gdipp {
Static ObjList := []
Static __New() {
this.LoadConstants()
}
Static BGR_RGB(_c) { ; this conversion works both ways, it ignores 0xFF000000
return (_c & 0xFF)<<16 | (_c & 0xFF00) | (_c & 0xFF0000)>>16 | (_c & 0xFF000000)
}
Static AGBR_RGBA(_c) { ; full reversal of ABGR/RGBA
return (_c & 0xFF)<<16 | (_c & 0xFF00) | (_c & 0xFF0000)>>16 | (_c & 0xFF000000) >> 24
}
Static CleanUp() {
Loop gdipp.ObjList.Length ; destroy objects in reverse of creation
gdipp.ObjList.RemoveAt(gdipp.ObjList.Length)
}
Static CompatDC(in_hDC:="") {
If (in_hDC="")
hDC := DllCall("CreateCompatibleDC", "UPtr", 0, "UPtr") ; mem DC
Else If IsInteger(in_hDC)
hDC := DllCall("CreateCompatibleDC", "UPtr", in_hDC, "UPtr") ; DC based on input DC ptr
Else If (IsObject(in_hDC) And in_hDC.cType = "DC")
hDC := DllCall("CreateCompatibleDC", "UPtr", in_hDC.ptr, "UPtr") ; DC based on input DC obj
Else
hDC := "" ; unsupported, throw an error
If !hDC
throw Error("Compatible DC creation failed.`r`n`r`nA_LastError: " A_LastError)
return gdipp.DC([hDC,1])
}
Static GetDC(in_obj:=0) {
(Type(in_obj) = "Gui") ? (hwnd := in_obj.hwnd) : (hwnd := in_obj)
hDC := DllCall("user32\GetDC", "UPtr", hwnd, "UPtr")
if hDC {
obj := gdipp.DC([hDC,0])
(Type(in_obj) = "Gui") ? (obj.gui := in_obj) : (obj.gui := 0) ; if gui, attach to DC obj
return obj
} Else
Msgbox "ERROR: DC not created.`r`n`r`nA_LastError: " A_LastError
}
Static ImageFromFile(sFileName, ICM:=0) { ; from robodesign version
If !FileExist(sFileName)
throw Error("Image file does not exist:`r`n`r`n" sFileName)
hModule := DllCall("LoadLibrary", "Str", "gdiplus", "UPtr") ; success > 0
si := Buffer((A_PtrSize=8)?24:16,0), NumPut("UInt", 1, si)
r2 := DllCall("gdiplus\GdiplusStartup", "UPtr*", &pToken:=0, "UPtr", si.ptr, "UPtr", 0) ; success = 0
r1 := DllCall("gdiplus\GdipCreateBitmapFromFile" (ICM?"ICM":""), "Str", sFileName, "UPtr*", &old_image:=0)
If !old_image
throw Error("GDI+ Image object failed to load.")
DllCall("gdiplus\GdipCreateHBITMAPFromBitmap", "UPtr", old_image, "UPtr*", &hBMP:=0, "UInt", 0)
If !hBMP
throw Error("GDI+ Image object conversion to HBITMAP failed.")
DllCall("gdiplus\GdipDisposeImage", "UPtr", old_image)
r1 := DllCall("gdiplus\GdiplusShutdown", "UPtr", pToken)
DllCall("FreeLibrary", "UPtr", hModule)
return gdipp.Bitmap([hBMP,0]) ; bitmap_new
}
Static ObjLookup(in_ptr) {
For i, obj in this.ObjList
If (in_ptr = obj.ptr)
return obj
return "" ; if no match
}
; ===================================================================
; Base Obj
; ===================================================================
class base_obj {
__New(p*) { ; p1 = _gdipp // p2 = ptr
this.ptr := p[1][1] ; obj pointer
this.temp := false ; is obj temp or no?
If (this.cType = "DC") { ; GetDC = 0 // CreateCompatibleDC = 1
(p[1][2]=0) ? (this.release := "ReleaseDC") : (p[1][2]=1) ? (this.release := "DeleteDC") : ""
this.StretchBltMode := 3 ; 3 = ColorOnColor / 4 = Halftone - 3 is a good default for speed
this.gui := {hwnd:0}
this.StockObjects := Map(), this.StockObjects.CaseSense := false
} Else If (this.cType != "DC")
this.CurDC := 0
t := this.GetObjectType()
If (t="Bitmap") Or (t="Pen") Or (t="Brush") Or (t="ExtPen") Or (t="Font") ; maybe missing HPALLETTE
this.GetObject()
gdipp.ObjList.Push(this)
}
__Delete() {
this.ByeBye()
}
ByeBye() {
r := ""
; If !this.ptr Or this.HasProp("gui") ; DC from hwnd is destroyed as window is destroyed
; return
If (this.cType = "DC") {
; For name, ptr in this.StockObjects ; clean up ejected stock objects
; DllCall("DeleteObject", "UPtr", ptr)
If (this.release = "ReleaseDC")
r1 := DllCall("ReleaseDC", "UPtr", this.gui.hwnd, "UPtr", this.ptr)
Else
r1 := DllCall("DeleteDC", "UPtr", this.ptr)
} Else
r1 := DllCall("DeleteObject", "UPtr", this.ptr)
If (r1="")
throw Error("Error on obj release, or object not yet supported."
,,"Obj Type: " this.cType "`r`nObj Ptr: " this.ptr)
}
Clean_Up() {
Loop gdipp.ObjList.Length {
obj := gdipp.ObjList[i := A_Index]
If (obj.ptr = this.ptr) {
gdipp.ObjList.RemoveAt(i)
Break
}
}
}
Destroy() {
this.Clean_Up()
}
GetInfo(in_ptr:="") {
obj_type := this.GetObjectType()
oi_size := DllCall("GetObject", "UPtr", (in_ptr?in_ptr:this.ptr), "Int", 0, "UPtr", 0)
oi:=Buffer((A_PtrSize = 8) ? 104 : 84, 0)
DllCall("GetObject", "UPtr", (in_ptr?in_ptr:this.ptr), "Int", oi.size, "UPtr", oi.ptr)
msgbox "Return Size: " oi_size "`r`n`r`n"
. "Type: " NumGet(oi,0,"UInt") "`r`n"
. "Width: " NumGet(oi, 4, "UInt") "`r`n"
. "Height: " NumGet(oi, 8, "UInt") "`r`n"
. "Stride: " NumGet(oi, 12, "UInt") "`r`n"
. "Planes: " NumGet(oi, 16, "UShort") "`r`n"
. "bpp: " NumGet(oi, 18, "UShort") "`r`n"
. "bPtr: " NumGet(oi, 24, "UPtr") "`r`n`r`n"
. "DIBSECTION struct:`r`n"
. "Struct: " NumGet(oi,32,"UInt") "`r`n"
. "Width: " NumGet(oi, 36, "UInt") "`r`n"
. "Height: " NumGet(oi, 40, "UInt") "`r`n"
. "Planes: " NumGet(oi, 44, "UShort") "`r`n"
. "bpp: " NumGet(oi, 46, "UShort") "`r`n"
. "Comp: " NumGet(oi, 48, "UInt") "`r`n"
. "Size: " NumGet(oi, 52, "UInt") "`r`n"
. "ClrUsed: " NumGet(oi, 60, "UInt") "`r`n"
. "ClrImportant: " NumGet(oi, 64, "UInt")
}
GetObject(in_ptr:="", show:=false) { ; get/refresh object properties
iSize := DllCall("GetObject", "UPtr", (in_ptr ? in_ptr : this.ptr), "UInt", 0, "UPtr", 0)
obj_type := this.GetObjectType()
If (obj_type = "Bitmap")
iSize := (A_PtrSize = 8) ? 104 : 84
info := Buffer(iSize,0)
iWritten := DllCall("GetObject", "UPtr", (in_ptr ? in_ptr : this.ptr), "UInt", iSize, "UPtr", info.ptr)
first_elem := NumGet(info,"UInt")
If (this.cType = "Bitmap" And first_elem = 0) {
this.__w := NumGet(info,4,"UInt")
this.__h := NumGet(info,8,"UInt")
this.__stride := NumGet(info,12,"UInt")
this.__planes := NumGet(info,16,"UShort")
this.__bpp := NumGet(info,18,"UShort")
this.__bPtr := NumGet(info,(A_PtrSize=8)?24:20, "UPtr")
If (!this.__bPtr) { ; for DDB
this.__bpp := this.__stride
this.__stride := Round(this.__w * (this.__bpp/8))
}
} Else If (this.cType = "Brush") {
this.__style := NumGet(info,"UInt")
this.__color := NumGet(info,4,"UInt")
this.__hatch := NumGet(info,8,"UPtr")
}
info := ""
; need to add more entries for pens, brush, etc...
}
GetObjectType(in_ptr:="") {
Static types := ["Pen","Brush","DC","MetaDC","PAL","Font","Bitmap","Region"
, "MetaFile","MemDC","ExtPen","EnhMetaDC","EnhMetaFIle","ColorSpace"]
result := DllCall("gdi32\GetObjectType", "UPtr", in_ptr ? in_ptr : this.ptr)
return (!result) ? 0 : types[result]
}
GetStockObject(i) {
return DllCall("gdi32\GetStockObject", "Int", i)
}
TempObj(in_obj, op:="Draw") { ; we'll see how this goes...
If (in_obj.cType = "DC")
tempObj := in_obj
Else { ; select obj into temporary DC
this.SelectObject(tempObj := this.CompatDC(), in_obj)
tempObj.temp := true
}
return tempObj
}
cType {
get => StrReplace(this.__Class,"gdipp.","")
}
}
; ===================================================================
; Bitmap obj
; ===================================================================
class Bitmap extends gdipp.base_obj {
Clone(_type:="DIB", delete:=false) {
flags := (_type="DIB") ? 0x2000 : 0 ; 0x2000 = LR_CREATEDIBSECTION
flags := (delete) ? (flags | 0x8) : flags ; 0x8 = LR_COPYDELETEORG
handle := DllCall("user32\CopyImage", "UPtr", this.ptr ; image handle
, "UInt", 0 ; type / 0 = BITMAP / 1 = ICON / 2 = CURSOR
, "Int", 0, "Int", 0 ; cx / cy image size if icon
, "UInt", flags)
return gdipp.Bitmap([handle,0])
}
CopyToClipboard(_type:="DIB") { ; thanks to guest3456 (mmikeww) for several details to this function
r1 := DllCall("OpenClipboard", "UPtr", 0) ; 0 = current application
r2 := DllCall("EmptyClipboard")
If !r2 {
msgbox "Error: Clipboard could not be emptied."
DllCall("CloseClipboard")
Return
}
If (this.bPtr And _type="DIB") { ; If bPtr exists, then it's a DIB...
clip_type := 8 ; CF_DIB
bmp := this.Pack() ; use Pack() method
} Else { ; ... if not, it's a DDB.
clip_type := 2 ; CF_BITMAP
bmp := this.Clone("DDB") ; uses Clone() and DllCall(user32\CopyImage)
}
DllCall("SetClipboardData", "uint", clip_type, "UPtr", bmp.ptr)
DllCall("CloseClipboard")
}
Pack() { ; returns packed dib
oi:=Buffer((A_PtrSize = 8) ? 104 : 84, 0)
DllCall("GetObject", "UPtr", this.ptr, "int", oi.Size, "UPtr", oi.ptr)
pDib := Buffer(40+this.size)
r0 := DllCall("RtlMoveMemory", "UPtr", pDib.ptr, "UPtr", oi.ptr+((A_PtrSize=8)?32:24), "UPtr", 40)
r1 := DllCall("RtlMoveMemory", "UPtr", pDib.ptr+40, "UPtr", this.bPtr, "UPtr", this.size)
return pDib
}
ScaleToRect(w,h:=0) {
w := Round(w)
(h=0) ? h:=w : ""
h := Round(h)
xR := w/this.w, yR := h/this.h ; Define xRatio and yRatio for resize.
smallest := (xR<yR) ? "xR" : "yR" ; Identify smallest ratio.
new_W := Round(this.w * %smallest%) ; Apply ratios.
new_H := Round(this.h * %smallest%)
(w-new_W=1) ? new_W += 1 : "" ; Check for 1 px diff on both x and y axis.
(h-new_H=1) ? new_H += 1 : ""
new_X := (new_W=w) ? 0 : ((w//2)-(new_W//2)) ; Set new x.
new_Y := (new_H=h) ? 0 : ((h//2)-(new_H//2)) ; Set new y.
return {x:new_X, y:new_Y, w:new_W, h:new_H, rect:[new_X,new_Y,new_W,new_H]}
}
bpp {
get => this.__bpp
}
bPtr { ; pointer to bitmap data
get => this.__bPtr
}
planes { ; this is usually 1
get => this.__planes
}
size {
get => this.__h * this.__stride
}
stride {
get => this.__stride
}
type {
get => (this.bPtr) ? "DIB" : "DDB"
}
w {
get => this.__w
}
h {
get => this.__h
}
}
; ===================================================================
; Brush - mostly LOGBRUSH
; ===================================================================
; Brush & Hatch Styles: https://docs.microsoft.com/en-us/windows/win32/api/wingdi/ns-wingdi-logbrush
; - Brush: DibPattern, DibPattern8x8, DibPatternPT, Hatched, Hollow, Pattern, Pattern8x8, Solid (default)
; - Hatch: BDiagonal, Cross, DiagCross, FDiagonal, Horizontal (default), Vertical
; NOTE: For corresponding integer values, see constants below in .LoadConstants() method.
class Brush extends gdipp.base_obj {
}
; ===================================================================
; Device Context obj
; ===================================================================
class DC extends gdipp.base_obj { ; maybe have param to specify BltStretchMode()
delayMethod := "" ; for delayed drawing
delayParams := ""
__Call(_method, p) { ; so far this is for DelayDraw*() functions only...
If !this.HasMethod(method := StrReplace(_method,"Delay","")) {
msgbox "Invalid method called: " _method
return
} Else
SetTimer ObjBindMethod(this,"DelayDraw", method, p), -1
}
Clone() {
return this.CompatDC()
}
CompatDC(in_hDC:="") {
If (in_hDC="")
hDC := DllCall("CreateCompatibleDC", "UPtr", this.ptr, "UPtr") ; DC based on parent obj DC
Else If IsInteger(in_hDC)
hDC := DllCall("CreateCompatibleDC", "UPtr", in_hDC, "UPtr") ; DC based on input DC ptr (including 0 for mem DC)
Else If (IsObject(in_hDC) And in_hDC.cType = "DC")
hDC := DllCall("CreateCompatibleDC", "UPtr", in_hDC.ptr, "UPtr") ; DC based on input DC obj
Else
hDC := "" ; unsupported, throw an error
If !hDC
throw Error("Compatible DC creation failed.`r`n`r`nA_LastError: " A_LastError)
return gdipp.DC([hDC,1])
}
CreateBrush(_ColorRef:=0x000000, _type:="solid", _hatch:="Horizontal") {
LOGBRUSH := Buffer((A_PtrSize=8)?16:12,0)
BR_TYPE := IsInteger(_type) ? _type : gdipp.BrushTypes[_type]
COLORREF := gdipp.BGR_RGB(_ColorRef) ; reverse input RGB to BGR, leave alpha
HS_TYPE := IsInteger(_hatch) ? _hatch : gdipp.HatchTypes[_hatch]
NumPut("UInt", BR_TYPE, "UInt", COLORREF, "UPtr", HS_TYPE, LOGBRUSH) ; HS_TYPE can also be a ptr to a packed DIB
pLogbrush := DllCall("gdi32\CreateBrushIndirect", "UPtr", LOGBRUSH.ptr)
return gdipp.Brush([pLogbrush,0])
}
CreateBitmap(w, h) {
hBMP := DllCall("gdi32\CreateCompatibleBitmap", "UPtr", this.ptr, "Int", w, "Int", h)
return gdipp.Bitmap([hBMP,0])
}
CreateDIBSection(w, h, bpp:=32) {
bi := Buffer(40, 0)
NumPut("UInt", 40 ; struct size
,"UInt", w ; image width
,"UInt", h ; image height
,"UShort", 1 ; planes
,"UShort", bpp ; bpp / color depth
,"UInt", 0, bi) ;
hBMP := DllCall("gdi32\CreateDIBSection", "UPtr", this.ptr
, "UPtr", bi.ptr ; BITMAPINFO
, "UInt", Usage:=0
, "UPtr*", &ppvBits:=0
, "UPtr", hSection:=0
, "UInt", OffSet:=0, "UPtr")
return gdipp.Bitmap([hBMP,0])
}
CreateRectRgn(a:=0) {
(!a) ? (a:=[0,0,this.w,this.h]) : ""
If a.Length != 4
throw Error("Invalid RECT array.`r`n`r`nThis parameter needs 4 elements:`r`n`r`nLeft, Top, Right, Bottom")
hRgn := DllCall("gdi32\CreateRectRgn", "Int", a[1], "Int", a[2], "Int", a[3], "Int", a[4])
return gdipp.Region([hRgn,0])
}
DelayDraw(method, params) { ; Specifically for applying mode 4 (Halftone) on a Draw operation.
old_mode := this.StretchBltMode ; Usually this mode will cause a massive slow down by comparison. These Draw*Delay()
this.StretchBltMode := 4 ; variant methods are best used when this is a sort of "final" drawing operation (like
this.%method%(params*) ; exiting a sizing loop in a window). In the case of exiting a window sizing loop,
this.StretchBltMode := old_mode ; this prevents the window from possibly freezing.
}
Draw(in_obj, _d:=0, _s:=0, Raster:=0) { ; thanks to mmikeww, GeekDude, and robodesign for some details on this func
(!_d) ? (_d := [0,0]) : ""
(_d.Length=2) ? (_d.Push(in_obj.w), _d.Push(in_obj.h)) : ""
(!_s) ? _s := [0,0] : ""
tempObj := this.TempObj(in_obj) ; wrap non-DC Obj into temp DC or just return input DC
r1 := DllCall("gdi32\BitBlt", "UPtr", this.ptr, "int", _d[1], "int", _d[2], "int", _d[3], "int", _d[4] ; dest DC
, "UPtr", tempObj.ptr, "int", _s[1], "int", _s[2] ; src DC
, "UInt", Raster?Raster:0x00CC0020)
(tempObj.cType = "DC" And tempObj.temp) ? tempObj.Destroy() : "" ; destroy temp DC
return r1
}
DrawAlpha(in_obj, _d:=0, alpha:=255, _s:=0) { ; thanks to mmikeww, GeekDude, and robodesign for some details on this func
(!_d) ? (_d := [0,0]) : ""
(_d.Length=2) ? (_d.Push(in_obj.w), _d.Push(in_obj.h)) : ""
(!_s) ? _s := [0,0,in_obj.w,in_obj.h] : ""
tempObj := this.TempObj(in_obj) ; wrap non-DC Obj into temp DC or just return input DC
r1 := DllCall("msimg32\AlphaBlend", "UPtr", this.ptr, "int", _d[1], "int", _d[2], "int", _d[3], "int", _d[4] ; dest DC
, "UPtr", tempObj.ptr, "int", _s[1], "int", _s[2], "int", _s[3], "int", _s[4] ; src DC
, "UInt", alpha<<16|1<<24)
(tempObj.cType = "DC" And tempObj.temp) ? tempObj.Destroy() : "" ; destroy temp DC
return r1
}
DrawStretch(in_obj, _d:=0, _s:=0, Raster:=0) { ; thanks to mmikeww, GeekDude, and robodesign for some details on this func
(!_d) ? (_d := [0,0]) : ""
(_d.Length=2) ? (_d.Push(in_obj.w), _d.Push(in_obj.h)) : ""
(!_s) ? _s := [0,0,in_obj.w,in_obj.h] : ""
tempObj := this.TempObj(in_obj) ; wrap non-DC Obj into temp DC or just return input DC
r1 := DllCall("gdi32\StretchBlt", "UPtr", this.ptr, "int", _d[1], "int", _d[2], "int", _d[3], "int", _d[4] ; dest DC
, "UPtr", tempObj.ptr, "int", _s[1], "int", _s[2], "int", _s[3], "int", _s[4] ; src DC
, "UInt", Raster ? Raster : 0x00CC0020)
(tempObj.cType = "DC" And tempObj.temp) ? tempObj.Destroy() : "" ; destroy temp DC
return r1
}
DrawTrans(in_obj, _d:=0, _s:=0, trans_color:=0) { ; thanks to GeekDude and robodesign for his comments on this func
(!_d) ? (_d := [0,0]) : ""
(_d.Length=2) ? (_d.Push(in_obj.w), _d.Push(in_obj.h)) : ""
(!_s) ? _s := [0,0,in_obj.w,in_obj.h] : ""
tempObj := this.TempObj(in_obj) ; wrap non-DC Obj into temp DC or just return input DC
r1 := DllCall("msimg32\TransparentBlt", "UPtr", this.ptr, "int", _d[1], "int", _d[2], "int", _d[3], "int", _d[4] ; dest DC
, "UPtr", tempObj.ptr, "int", _s[1], "int", _s[2], "int", _s[3], "int", _s[4] ; src DC
, "UInt", trans_color)
(tempObj.cType = "DC" And tempObj.temp) ? tempObj.Destroy() : "" ; destroy temp DC
return r1
}
Ellipse(s) {
If Type(s) != "Array" Or s.Length != 4
throw Error("Invalid RECT parameter.",,"Format: [x, y, w, h]")
s[3] := s[1] + s[3] ; convert x, y, w, h to...
s[4] := s[2] + s[4] ; ... Left, Top, Right, Bottom
return DllCall("gdi32\Ellipse", "UPtr", this.ptr
, "Int", s[1], "Int", s[2], "Int", s[3], "Int", s[4]) ; Left, Top, Right, Bottom
}
ExcludeClipRect(a) {
If Type(a) != "Array" Or a.Length != 4
throw Error("Invalid RECT array.`r`n`r`nThis parameter needs 4 elements:`r`n`r`nLeft, Top, Right, Bottom")
a[3] := a[1] + a[3] ; convert x, y, w, h to...
a[4] := a[2] + a[4] ; ... Left, Top, Right, Bottom
return DllCall("gdi32\ExcludeClipRect", "UPtr", this.ptr
, "Int", a[1], "Int", a[2], "Int", a[3], "Int", a[4]) ; Left, Top, Right, Bottom
}
FillRect(_RECT:=0, hBrush:=0) {
(!_RECT) ? (_RECT := [0,0,this.w,this.h]) : "" ; apply to full DC when _RECT omitted
RECT := Buffer(16,0)
For i, value in _RECT
NumPut("UInt", value, RECT, (A_Index-1) * 4)
_brush := (!hBrush) ? hDC.DcBrush : hBrush.ptr ; use CurBrush or use specified brush
If !_brush
throw Error("Invalid brush selected for operation.")
return DllCall("user32\FillRect", "UPtr", this.ptr, "UPtr", RECT.ptr, "UPtr", _brush)
}
Flush() {
return DllCall("gdi32\GdiFlush")
}
GetBitmap(w:=0, h:=0, _type:="DIB", Raster:=0) { ; considering: _type:="DIB", always use default raster?
If (!w and !h and this.gui.hwnd)
this.gui.GetClientPos(,,&w,&h)
Else if (!w and !h)
w := this.w, h := this.h
If (_type="DIB")
new_BMP := this.CreateDIBSection(w, h) ; CreateBitmap / CreateDIBSection
Else
new_BMP := this.CreateBitmap(w, h)
tempDC := this.CompatDC()
tempDC.SelectObject(new_BMP)
tempDC.Draw(this)
tempDC.Destroy()
return new_BMP
}
LineTo(x, y) {
return DllCall("gdi32\LineTo", "UPtr", this.ptr, "Int", x, "Int", y)
}
Move(x, y, get_last:=false) {
If (get_last) {
POINT := Buffer(8,0)
get_last := POINT.ptr
}
result := DllCall("gdi32\MoveToEx", "UPtr", this.ptr, "Int", x, "Int", y, "UPtr", get_last)
(get_last) ? get_last := [NumGet(POINT,"UInt"), NumGet(POINT,4,"UInt")] : ""
return get_last
}
SelectObject(p*) {
If (p.Length = 1)
DC := this, CurObj := p[1]
Else If (p.Length = 2)
DC := p[1], CurObj := p[2]
Else If (!p.Length Or p.Length > 2)
throw Error("Invalid number of parameters.")
If IsInteger(CurObj) { ; stock object
; If (stock_obj := gdipp.GetFlag(CurObj,"StockObjectPtrs"))
; this.StockObjects.Delete(stock_obj) ; remove stock object from "ejected list"
old_ptr := DllCall("gdi32\SelectObject", "UPtr", DC.ptr, "UPtr", in_ptr := CurObj)
} Else { ; wrapped object
CurObj.CurDC := DC ; set obj.CurDC in the obj
old_ptr := DllCall("gdi32\SelectObject", "UPtr", DC.ptr, "UPtr", in_ptr := CurObj.ptr)
}
If (old_obj_class := gdipp.ObjLookup(old_ptr))
old_obj_class.CurDC := 0 ; reset .CurDC in old_obj_class if exist
; Else If (stock_obj := gdipp.GetFlag(old_ptr,"StockObjectPtrs"))
; this.StockObjects[stock_obj] := old_ptr ; catalog stock obj in "ejected list"
If (IsObject(CurObj) And CurObj.cType = "Region")
CurObj.Destroy()
return old_ptr
}
SetBrushOrg(x, y, get_last:=false) {
If (get_last) {
POINT := Buffer(8,0)
get_last := POINT.ptr
}
result := DllCall("gdi32\SetBrushOrgEx", "UPtr", this.ptr, "Int", x, "Int", y, "UPtr", get_last)
(get_last) ? get_last := [NumGet(POINT,"UInt"), NumGet(POINT,4,"UInt")] : ""
return get_last
}
; ====================================================================
; DC Properties
; ====================================================================
; https://docs.microsoft.com/en-us/windows/win32/api/wingdi/nf-wingdi-getgraphicsmode
GraphicsMode { ; GM_COMPATIBLE = 1 (default) /// GM_ADVANCED = 2
set => DllCall("gdi32\SetGraphicsMode", "UPtr", this.ptr, "Int", value)
get => DllCall("gdi32\GetGraphicsMode", "UPtr", this.ptr)
}
; https://docs.microsoft.com/en-us/windows/win32/api/wingdi/nf-wingdi-getmapmode
; MM_ANISOTROPIC 8 Allows x/y coords to be adjusted independently.
;
; MM_ISOTROPIC 7 Ensures a 1:1 apsect ratio.
;
; MM_TEXT (default) 1 Useful for drawing on varied pixel size (from
; device to device.
;
; MM_HIENGLISH 5 Useful for drawing in inches/millimeters.
; MM_HIMETRIC 3
; MM_LOENGLISH 4
; MM_LOMETRIC 2
; MM_TWIPS 6
MapMode {
set => DllCall("gdi32\SetMapMode", "UPtr", this.ptr, "Int", value)
get => DllCall("gdi32\GetMapMode", "UPtr", this.ptr)
}
;https://docs.microsoft.com/en-us/windows/win32/api/wingdi/nf-wingdi-setmapperflags
;
; Specifies whether the font mapper should attempt to match a font's aspect ratio to the current device's
; aspect ratio. If bit zero is set, the mapper selects only matching fonts.
MapperFlags {
set => DllCall("gdi32\SetMapperFlags", "UPtr", this.ptr, "UInt", value)
get => DllCall("gdi32\GetMapperFlags", "UPtr", this.ptr)
}
; https://docs.microsoft.com/en-us/windows/win32/api/wingdi/nf-wingdi-getstretchbltmode
; BLACKONWHITE = 1
; WHITEONBLACK = 2
; COLORONCOLOR = 3 (default for all DC's in this lib)
; HALFTONE = 4
; STRETCH_ANDSCANS = BLACKONWHITE
; STRETCH_DELETESCANS = COLORONCOLOR
; STRETCH_HALFTONE = HALFTONE
; STRETCH_ORSCANS = WHITEONBLACK
;
; Without ColorOnColor or Halftone set, you are likely to get color distortion,
; especially if you are trying to draw an image loaded from a 24-bit source,
; like JPEG.
StretchBltMode {
set => DllCall("gdi32\SetStretchBltMode", "UPtr", this.ptr, "Int", value)
get => DllCall("gdi32\GetStretchBltMode", "UPtr", this.ptr)
}
; ====================================================================
; Stock Object pointers
; ====================================================================
AnsiFixedFont {
get => DllCall("gdi32\GetStockObject", "Int", 11)
}
AnsiVarFont {
get => DllCall("gdi32\GetStockObject", "Int", 12)
}
BlackBrush {
get => DllCall("gdi32\GetStockObject", "Int", 4)
}
BlackPen {
get => DllCall("gdi32\GetStockObject", "Int", 7)
}
DcBitmap {
get => DllCall("gdi32\GetStockObject", "Int", 21) ; not documented
}
DcBrush {
get => DllCall("gdi32\GetStockObject", "Int", 18)
}
DcColorSpace {
get => DllCall("gdi32\GetStockObject", "Int", 20) ; not documented
}
DcPen {
get => DllCall("gdi32\GetStockObject", "Int", 19)
}
DefaultDeviceFont {
get => DllCall("gdi32\GetStockObject", "Int", 14)
}
DefaultGuiFont {
get => DllCall("gdi32\GetStockObject", "Int", 17)
}
DefaultPallette {
get => DllCall("gdi32\GetStockObject", "Int", 15)
}
DkGrayBrush {
get => DllCall("gdi32\GetStockObject", "Int", 3)
}
GrayBrush {
get => DllCall("gdi32\GetStockObject", "Int", 2)
}
LtGrayBrush {
get => DllCall("gdi32\GetStockObject", "Int", 1)
}
NullBrush {
get => DllCall("gdi32\GetStockObject", "Int", 5) ; aka Hollow_Brush
}
NullPen {
get => DllCall("gdi32\GetStockObject", "Int", 8)
}
OemFixedFont {
get => DllCall("gdi32\GetStockObject", "Int", 10)
}
SystemFixedFont {
get => DllCall("gdi32\GetStockObject", "Int", 16)
}
SystemFont {
get => DllCall("gdi32\GetStockObject", "Int", 13)
}
WhiteBrush {
get => DllCall("gdi32\GetStockObject", "Int", 0)
}
WhitePen {
get => DllCall("gdi32\GetStockObject", "Int", 6)
}
; ====================================================================
; Stock Object properties
; ====================================================================
BgMode {
get {
return DllCall("gdi32\GetBkMode", "UPtr", this.ptr) ; Transparent = 1 // Opaque = 2
}
set {
DllCall("gdi32\SetBkMode", "UPtr", this.ptr, "Int", value)
}
}
BgColor {
get {
return gdipp.BGR_RGB(DllCall("gdi32\GetBkColor", "UPtr", this.ptr))
}
set {
DllCall("gdi32\SetBkColor", "UPtr", this.ptr, "Int", gdipp.BGR_RGB(value))
}
}
BrushColor {
get => gdipp.BGR_RGB(DllCall("gdi32\GetDCBrushColor", "UPtr", this.ptr))
set => DllCall("gdi32\SetDCBrushColor", "UPtr", this.ptr, "Int", gdipp.BGR_RGB(value))
}
PenColor {
get => gdipp.BGR_RGB(DllCall("gdi32\GetDCPenColor", "UPtr", this.ptr))
set => DllCall("gdi32\SetDCPenColor", "UPtr", this.ptr, "Int", gdipp.BGR_RGB(value))
}
; ====================================================================
; properties from GetDeviceCaps
; ====================================================================
AspectX {
get => gdipp.GetDeviceCaps(this.ptr, 40)
}
AspectY {
get => gdipp.GetDeviceCaps(this.ptr, 42)
}
AspectXY {
get => gdipp.GetDeviceCaps(this.ptr, 44)
}
BltAlignment {
get => gdipp.GetDeviceCaps(this.ptr, 119)
}
bpp {
get => gdipp.GetDeviceCaps(this.ptr, 12)
}
ColorRes {
get => this.GetDeviceCaps(this.ptr, 108)
}
DpiX {
get => this.GetDeviceCaps(this.ptr, 88)
}
DpiY {
get => this.GetDeviceCaps(this.ptr, 90)
}
DesktopH {
get => this.GetDeviceCaps(this.ptr, 117)
}
DesktopW {
get => this.GetDeviceCaps(this.ptr, 118)
}
DriverVersion {
get => this.GetDeviceCaps(this.ptr, 0)
}
mmX {
get => this.GetDeviceCaps(this.ptr, 4)
}
mmY {
get => this.GetDeviceCaps(this.ptr, 6)
}
NumBrushes {
get => this.GetDeviceCaps(this.ptr, 16)
}
NumColors {
get => this.GetDeviceCaps(this.ptr, 24)
}
NumFonts {
get => this.GetDeviceCaps(this.ptr, 22)
}
NumMarkers {
get => this.GetDeviceCaps(this.ptr, 20)
}
NumPens {
get => this.GetDeviceCaps(this.ptr, 18)
}
PaletteSize {
get => this.GetDeviceCaps(this.ptr, 104)
}
PDeviceSize {
get => this.GetDeviceCaps(this.ptr, 26)
}
PhysicalOffsetX {
get => this.GetDeviceCaps(this.ptr, 112)
}
PhysicalOffsetY {
get => this.GetDeviceCaps(this.ptr, 113)
}
PhysicalW {
get => this.GetDeviceCaps(this.ptr, 110)
}
PhysicalH {
get => this.GetDeviceCaps(this.ptr, 111)
}
Planes {
get => this.GetDeviceCaps(this.ptr, 14)
}
ScalingFactorX {
get => this.GetDeviceCaps(this.ptr, 114)
}
ScalingFactorY {
get => this.GetDeviceCaps(this.ptr, 115)
}
VRefresh {
get => this.GetDeviceCaps(this.ptr, 116)
}
w {
get => this.GetDeviceCaps(this.ptr, 8)
}
h {
get => this.GetDeviceCaps(this.ptr, 10)
}
gW { ; get attached gui width, if gui attached
get {
If (!this.gui.hwnd)
return 0
Else {
this.gui.GetClientPos(,,&w)
return w
}
}
}
gH { ; get attached gui height, if gui attached
get {
If (!this.gui.hwnd)
return 0
Else {
this.gui.GetClientPos(,,,&h)
return h
}
}
}
GetDeviceCaps(hdc, index) { ; (https://docs.microsoft.com/en-us/windows/win32/api/wingdi/nf-wingdi-getdevicecaps)
return DllCall("gdi32\GetDeviceCaps", "UPtr", hDC, "int", index) ; thanks to mmikeww, GeekDude, and robodesign for these docs!
}
}
; ===================================================================
; Font
; ===================================================================
class Font extends gdipp.base_obj {
}
; ===================================================================
; Pen
; ===================================================================
class Pen extends gdipp.base_obj {
}
; ===================================================================
; Region
; ===================================================================
class Region extends gdipp.base_obj {
}
; =============================================================================================
; method for loading constants - so we can turn CaseSense off in Map()
; =============================================================================================
Static LoadConstants() {
; Brush Types (0-3, 5-8) ; https://docs.microsoft.com/en-us/windows/win32/api/wingdi/ns-wingdi-logbrush
bt := Map(), bt.CaseSense := false
bt["Solid"] := 0
, bt["Hollow"] := 1
, bt["Hatched"] := 2
, bt["Pattern"] := 3
, bt["DibPattern"] := 5
, bt["DibPatternPT"] := 6
, bt["Pattern8x8"] := 7
, bt["DibPattern8x8"] := 8
this.BrushTypes := bt
; Hatch Styles (0-5) ; https://docs.microsoft.com/en-us/windows/win32/api/wingdi/ns-wingdi-logbrush
ht := Map(), ht.CaseSense := false
ht["Horizontal"] := 0
, ht["Vertical"] := 1
, ht["FDiagonal"] := 2
, ht["BDiagonal"] := 3
, ht["Cross"] := 4
, ht["DiagCross"] := 5
this.HatchTypes := ht
; Stock Object types (1-14) ; https://docs.microsoft.com/en-us/windows/win32/api/wingdi/nf-wingdi-getstockobject
so := Map(), so.CaseSense := false
so["WhiteBrush"] := 0
, so["LtGrayBrush"] := 1
, so["GrayBrush"] := 2
, so["DkGrayBrush"] := 3
, so["BlackBrush"] := 4
, so["HollowBrush"] := 5 ; a.k.a. NULL_BRUSH
, so["WhitePen"] := 6
, so["BlackPen"] := 7
, so["NullPen"] := 8
, so["_Unknown_9"] := 9 ; always returns 0 (so far)
, so["OemFixedFont"] := 10
, so["AnsiFixedFont"] := 11
, so["AnsiVarFont"] := 12
, so["SystemFont"] := 13
, so["DefaultDeviceFont"] := 14
, so["DefaultPallette"] := 15
, so["SystemFixedFont"] := 16
, so["DefaultGuiFont"] := 17
, so["DcBrush"] := 18
, so["DcPen"] := 19
, so["DcColorSpace"] := 20 ; not documented
, so["DcBitmap"] := 21 ; not documented
this.StockObjectTypes := so
sop := Map(), sop.CaseSense := false ; StockObjectPtrs
For name, val in so
If (name != "_Unknown_9")
sop[name] := DllCall("gdi32\GetStockObject", "Int", val)
this.StockObjectPtrs := sop
}
Static GetFlag(iInput,member) { ; reverse lookup for Map() constants
For prop, value in gdipp.%member%
If (iInput = value)
return prop
return "" ; if no match
; throw Error("GetFlag() method: Value not listed.`r`n`r`nValue: " iInput)
}
Static InArray(arr,in_val) {
For i, value in arr
If (in_val = value)
return i
return false ; if no match
}
; ===================================================================
; GDIP sub class
; ===================================================================
class p {
Static Startup() {
this.hModule := DllCall("LoadLibrary", "Str", "gdiplus", "UPtr") ; success > 0
Static si := Buffer((A_PtrSize=8)?24:16,0)
NumPut("UInt", 1, si)
r2 := DllCall("gdiplus\GdiplusStartup", "UPtr*", &pToken:=0, "UPtr", si.ptr, "UPtr", 0) ; success = 0
this.token := pToken
}
Static Shutdown() {
r1 := DllCall("gdiplus\GdiplusShutdown", "UPtr", this.token)
}
}
}
; ===============================================================================
; ===============================================================================
; Common Structures in Class wrappers
; ===============================================================================
; ===============================================================================
class LOGFONT {
__New() {
}
}
/**
* Bilinear resize ARGB image.
* pixels is an array of size w * h.
* Target dimension is w2 * h2.
* w2 * h2 cannot be zero.
*
* @param pixels Image pixels.
* @param w Image width.
* @param h Image height.
* @param w2 New width.
* @param h2 New height.
* @return New array with size w2 * h2.
*/
; public int[] resizeBilinear(int[] pixels, int w, int h, int w2, int h2) {
; int[] temp = new int[w2*h2] ;
; int a, b, c, d, x, y, index ;
; float x_ratio = ((float)(w-1))/w2 ;
; float y_ratio = ((float)(h-1))/h2 ;
; float x_diff, y_diff, blue, red, green ;
; int offset = 0 ;
; for (int i=0;i<h2;i++) {
; for (int j=0;j<w2;j++) {
; x = (int)(x_ratio * j) ;
; y = (int)(y_ratio * i) ;
; x_diff = (x_ratio * j) - x ;
; y_diff = (y_ratio * i) - y ;
; index = (y*w+x) ;
; a = pixels[index] ;
; b = pixels[index+1] ;
; c = pixels[index+w] ;
; d = pixels[index+w+1] ;
; // blue element
; // Yb = Ab(1-w)(1-h) + Bb(w)(1-h) + Cb(h)(1-w) + Db(wh)
; blue = (a&0xff)*(1-x_diff)*(1-y_diff) + (b&0xff)*(x_diff)*(1-y_diff) +
; (c&0xff)*(y_diff)*(1-x_diff) + (d&0xff)*(x_diff*y_diff);
; // green element
; // Yg = Ag(1-w)(1-h) + Bg(w)(1-h) + Cg(h)(1-w) + Dg(wh)
; green = ((a>>8)&0xff)*(1-x_diff)*(1-y_diff) + ((b>>8)&0xff)*(x_diff)*(1-y_diff) +
; ((c>>8)&0xff)*(y_diff)*(1-x_diff) + ((d>>8)&0xff)*(x_diff*y_diff);
; // red element
; // Yr = Ar(1-w)(1-h) + Br(w)(1-h) + Cr(h)(1-w) + Dr(wh)
; red = ((a>>16)&0xff)*(1-x_diff)*(1-y_diff) + ((b>>16)&0xff)*(x_diff)*(1-y_diff) +
; ((c>>16)&0xff)*(y_diff)*(1-x_diff) + ((d>>16)&0xff)*(x_diff*y_diff);
; temp[offset++] =
; 0xff000000 | // hardcode alpha
; ((((int)red)<<16)&0xff0000) |
; ((((int)green)<<8)&0xff00) |
; ((int)blue) ;
; }
; }
; return temp ;
; }