build.gradle

plugins {
	id 'fabric-loom' version '0.8-SNAPSHOT'
	id 'maven-publish'
}

sourceCompatibility = JavaVersion.VERSION_16
targetCompatibility = JavaVersion.VERSION_16

archivesBaseName = project.archives_base_name
version = project.mod_version
group = project.maven_group

repositories {
	maven {
		name = "dblsaiko"
		url = "https://maven.dblsaiko.net/"
	}
	maven {
		name = "CottonMC"
		url = "https://server.bbkr.space/artifactory/libs-release"
	}
	maven {url "https://maven.jamieswhiteshirt.com/libs-release/"}
	maven {
		name = 'Ladysnake Mods'
		url = 'https://ladysnake.jfrog.io/artifactory/mods'
		content {
			includeGroup 'io.github.ladysnake'
			includeGroupByRegex 'io\\.github\\.onyxstudios.*'
		}
	}
	maven { url 'https://maven.blamejared.com' }
	maven {
		name = "Technici4n"
		url = "https://raw.githubusercontent.com/Technici4n/Technici4n-maven/master/"
		content {
			includeGroup "net.fabricmc.fabric-api" // until fabric-api-lookup-api-v1 is merged
			includeGroup "dev.technici4n"
		}
	}
	maven {
		url = 'https://raw.githubusercontent.com/Devan-Kerman/Devan-Repo/master/'
	}
	maven {
		url "https://maven.shedaniel.me/"
		content {
			includeGroup "dev.architectury"
			includeGroup "me.shedaniel"
			includeGroup "me.shedaniel.cloth"
			includeGroup "me.shedaniel.cloth.api"
		}
	}
	maven {
		name = "BuildCraft"
		url = "https://mod-buildcraft.com/maven"
	}
	maven {
		name "Siphalor's Maven"
		url "https://maven.siphalor.de"
	}
	maven {
		name = "TerraformersMC"
		url = "https://maven.terraformersmc.com/"
	}
	maven {
		name = "NerdHubMC"
		url = "https://maven.abusedmaster.xyz/"
	}
	maven { url "https://jitpack.io" }

	jcenter()

	mavenCentral()

	maven { url = "https://hephaestus.dev/release" }

}

dependencies {

	dependencies.ext.lib = { dep, optional = false ->
		modImplementation(dep) {
			if (!dep.contains("dev.technici4n"))
				exclude group: "net.fabricmc.fabric-api"
			exclude group: "com.jamieswhiteshirt"
			exclude group: "io.github.prospector"
		}
		if (!optional) {
			include(dep) {
				if (!dep.contains("dev.technici4n"))
					exclude group: "net.fabricmc.fabric-api"
				exclude group: "com.jamieswhiteshirt"
				exclude group: "io.github.prospector"
			}
		}
	}

	//	???
	implementation include("blue.endless:jankson:1.2.1")

	//	Fabric
	minecraft "com.mojang:minecraft:${project.minecraft_version}"
	mappings "net.fabricmc:yarn:${project.yarn_mappings}:v2"
	modImplementation "net.fabricmc:fabric-loader:${project.loader_version}"
	modImplementation "net.fabricmc.fabric-api:fabric-api:${project.fabric_version}"

	//	Internal
	modImplementation include("com.github.Archydra-Studios:Incubus-Core:${project.incubus_version}")
	modImplementation include("io.github.Dragonoidzero:Fabric-ASM:v2.3")

	//	Dependencies
	modImplementation include("io.github.cottonmc:LibGui:${project.libgui_version}")
	modImplementation include("com.jamieswhiteshirt:reach-entity-attributes:${project.reach_version}")
	modImplementation include("io.github.ladysnake:PlayerAbilityLib:${project.pal_version}")
	modImplementation include("dev.emi:trinkets:${project.trinkets_version}")
	modImplementation include("dev.technici4n:FastTransferLib:${project.ftl_version}")
	modRuntime include("vazkii.patchouli:Patchouli:${project.patchouli_version}")

	modImplementation include("io.github.onyxstudios.Cardinal-Components-API:cardinal-components-base:${project.cardinal_version}")
	modImplementation include("io.github.onyxstudios.Cardinal-Components-API:cardinal-components-world:${project.cardinal_version}")

	//	Integration
	modImplementation "me.shedaniel:RoughlyEnoughItems-fabric:${project.rei_version}"

	//	Testing
	modRuntime "com.terraformersmc:modmenu:${project.modmenu_version}"
}

processResources {
	inputs.property "version", project.version

	filesMatching("fabric.mod.json") {
		expand "version": project.version
	}
}

tasks.withType(JavaCompile).configureEach {
	// ensure that the encoding is set to UTF-8, no matter what the system default is
	// this fixes some edge cases with special characters not displaying correctly
	// see http://yodaconditions.net/blog/fix-for-java-file-encoding-problems-with-gradle.html
	// If Javadoc is generated, this must be specified in that task too.
	it.options.encoding = "UTF-8"

	// Minecraft 1.17 (21w19a) upwards uses Java 16.
	it.options.release = 16
}

java {
	// Loom will automatically attach sourcesJar to a RemapSourcesJar task and to the "build" task
	// if it is present.
	// If you remove this line, sources will not be generated.
	withSourcesJar()
}

jar {
	from("LICENSE") {
		rename { "${it}_${project.archivesBaseName}"}
	}
}

// configure the maven publication
publishing {
	publications {
		mavenJava(MavenPublication) {
			// add all the jars that should be included when publishing to maven
			artifact(remapJar) {
				builtBy remapJar
			}
			artifact(sourcesJar) {
				builtBy remapSourcesJar
			}
		}
	}

	// select the repositories you want to publish to
	repositories {
		// uncomment to publish to the local maven
		mavenLocal()

	}
}