forked from jaegertracing/jaeger-client-java
-
Notifications
You must be signed in to change notification settings - Fork 0
/
build.gradle
93 lines (74 loc) · 2.36 KB
/
build.gradle
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
plugins {
id "org.jruyi.thrift" version "0.3.1"
id "jacoco"
id "com.github.kt3k.coveralls" version "2.5.0"
id "com.github.hierynomus.license" version "0.12.1"
id 'com.github.sherter.google-java-format' version '0.3.2'
id "com.github.johnrengelman.shadow" version "1.2.3"
id "net.ltgt.errorprone" version "0.0.8"
}
ext.opentracingVersion = '0.15.0'
ext.guavaVersion = '18.0'
ext.apacheThriftVersion = '0.9.2'
ext.jerseyVersion = '2.22.2'
ext.slf4jVersion = '1.7.16'
ext.jacksonVersion = '2.7.4'
ext.apacheHttpComponentsVersion = '4.1.2'
ext.junitVersion = '4.12'
ext.mockitoVersion = '2.0.2-beta'
allprojects {
apply plugin: 'idea' // intellij support
group = 'com.uber.jaeger'
version = '0.16.0-SNAPSHOT'
task wrapper(type: Wrapper) {
gradleVersion = '2.12' //version required
}
}
subprojects {
apply plugin: 'com.github.hierynomus.license'
apply plugin: 'java'
apply plugin: 'maven'
apply plugin: 'signing'
sourceCompatibility = 1.7
targetCompatibility = 1.7
[compileJava, compileTestJava, javadoc]*.options*.encoding = 'UTF-8'
repositories {
mavenCentral()
}
task listJars(description: 'Display all compile jars.') << {
configurations.compile.each { File file -> println file.name }
}
task verifyFormatting(type: com.github.sherter.googlejavaformatgradleplugin.VerifyGoogleJavaFormat) {
exclude '**/gen-java/**'
}
license {
header rootProject.file('license-template')
strictCheck true
include "**/*.java"
excludes(["**/gen-java/**"])
ext.year = Calendar.getInstance().get(Calendar.YEAR)
ext.name = 'Uber Technologies, Inc'
ignoreFailures = false
mapping {
java = 'SLASHSTAR_STYLE'
}
}
classes.dependsOn tasks.licenseFormat
classes.dependsOn tasks.verifyFormatting
apply from: '../gradle/publish.gradle'
test {
testLogging {
events "failed"
exceptionFormat "full"
// remove standard output/error logging from --info builds
// by assigning only 'failed' and 'skipped' events
info.events = ["failed", "skipped"]
}
}
dependencies {
compileOnly 'org.projectlombok:lombok:1.16.10'
}
}
configure(subprojects.findAll {it.name != 'jaeger-thrift'}) {
apply plugin: 'net.ltgt.errorprone'
}