Create vfat slot with multiple files from Yocto

[Hollingsworth-martin-bl]

Hello community,
I have a bundle where one slot is a vfat (fat32) filesystem with multiple files inside (i.e. my boot partition). When generating the bundle from within yocto how do I configure the slot appropriately?

With the Yocto WKS system I can conveniently configure the partition as fat32 and list all files to be installed from ${DEPLOY_DIR_IMAGE} into the partition using ${IMAGE_BOOT_FILES} variable (see kickstart.rst in yocto documentation).

For a rauc bundle I have not found something similar and use this workaround:

• configure the slot as RAUC_SLOT_bootloader[fstype] = "vfat"
• write an extra yocto recipe which creates a fat32 filesystem image and fills it with the files
• Use the build output of the recipe as content of the rauc slot

It works stable, but its hard to read and error prone because the content of the wic file and the rauc bundle might drift apart. Any ideas? Thanks!

Regards, Martin

[mdsketch]

Any chance you can share how you made your work around. I am having the same issue, however for right now your work around sounds like it could be enough for me

[mdsketch]

It looks like if you add rpi-sdimg to you IMAGE_FSTYPES it will output the vfat image

Then my output bundle contains:

[Hollingsworth-martin-bl]

Hey @mdsketch,
your suggestion with the rpi-sdimg seems to be a specific solution for RPi (raspberry-pi). Here are some details on my solution which I use for Xilinx ZynqMP which needs a vfat bootloader partition.

The *.wks file creates the regular yocto image, the content of the vfat bootloader partition points to bootimg-partition, which is defined by $IMAGE_BOOT_FILES (see the yocto documentation).

# bootloder.0
part --source bootimg-partition --ondisk mmcblk1 --fstype=vfat --label boot0 --active --align 4 --fixed-size 128M
# bootloader.1
part --source bootimg-partition --ondisk mmcblk1 --fstype=vfat --label boot1 --active --align 4 --fixed-size 128M
# rootfs.0 partition
part --source rootfs --ondisk mmcblk1 --fstype=ext4 --label root0 --align 4 --fixed-size 4096M
# rootfs.1 partition
part --source rootfs --ondisk mmcblk1 --fstype=ext4 --label root1 --align 4 --fixed-size 4096M

I define my rauc bundle as follows, the bootloader slot is defined as RAUC_SLOT_bootloader[fstype] = "vfat", for the content of the partition I refer yocto to a special image recipe RAUC_SLOT_bootloader = "my-image-bootfs":

inherit bundle

RAUC_BUNDLE_COMPATIBLE = "${MACHINE}"
RAUC_BUNDLE_VERSION = "dev"
RAUC_BUNDLE_DESCRIPTION = "development bundle"
RAUC_BUNDLE_BUILD = "${DATETIME}"
RAUC_BUNDLE_FORMAT = "plain"

# Slots included in the bundle
RAUC_BUNDLE_SLOTS = "bootloader rootfs"

# Bootloader slot content
RAUC_SLOT_bootloader = "my-image-bootfs"
RAUC_SLOT_bootloader[fstype] = "vfat"

# Rootfs slot content
RAUC_SLOT_rootfs = "my-image"
RAUC_SLOT_rootfs[fstype] = "ext4"

And here the recipe my-image-bootfs that creates the actual vfat image file:

inherit deploy

DEPENDS += " \
    dosfstools-native \
    mtools-native \
"

do_fetch[noexec] = "1"
do_unpack[noexec] = "1"
do_patch[noexec] = "1"

S = "${WORKDIR}"
IMAGE_NAME = "${PN}-${MACHINE}.vfat"
IMAGE_FILE = "${WORKDIR}/${IMAGE_NAME}"

IMAGE_DEPLOY_NAME = "${BPN}-${PKGE}-${PKGV}-${PKGR}-${MACHINE}-${DATETIME}.vfat"
IMAGE_DEPLOY_NAME[vardepsexclude] = "DATETIME"

do_configure() {
    rm -f ${IMAGE_FILE}
    rm -f ${D}/${IMAGE_DEPLOY_NAME}
    rm -f ${DEPLOYDIR}/${IMAGE_DEPLOY_NAME}
}

do_compile[vardeps] = "IMAGE_BOOT_FILES"

# Create 128MiB fat filesystem image and add boot files from IMAGE_BOOT_FILES.
# The following list is manually curated, keep in synch with IMAGE_BOOT_FILES!
do_compile() {
    dd if=/dev/zero of=${IMAGE_FILE} bs=1M count=128
    mkfs.vfat ${IMAGE_FILE}
    mcopy -i ${IMAGE_FILE} ${DEPLOY_DIR_IMAGE}/BOOT.bin ::BOOT.bin
    mcopy -i ${IMAGE_FILE} ${DEPLOY_DIR_IMAGE}/boot.scr ::boot.scr
    mcopy -i ${IMAGE_FILE} ${DEPLOY_DIR_IMAGE}/Image ::Image
    if [ ! -e ${IMAGE_FILE} ]; then
        bbfatal_log "Failed to generate boot partition image!"
    fi
}

do_install() {
    install -d ${D}
    install -m 0644 ${IMAGE_FILE} ${D}/${IMAGE_DEPLOY_NAME}
}

INSANE_SKIP:${PN} += "installed-vs-shipped"

do_deploy() {
    install -d ${DEPLOYDIR}
    install -m 0644 ${IMAGE_FILE} ${DEPLOYDIR}/${IMAGE_DEPLOY_NAME}
    ln -sf ${IMAGE_DEPLOY_NAME} ${DEPLOYDIR}/${IMAGE_NAME}
}

# Empty function to satisfy rauc bundle dependecy to do_image_complete()
do_image_complete() {
}

FILES:${PN} += " ${DEPLOYDIR}/${IMAGE_DEPLOY_NAME} ${DEPLOYDIR}/${IMAGE_NAME}"

addtask deploy after do_compile
addtask do_image_complete after do_deploy

[mdsketch]

Thanks for that, indeed I'm using the raspberry-pi. I'm actually going to use your recipe as a template to create another partition image for the pi (autoboot.txt) so I can chose which boot part to load.

You might want to look at https://github.com/agherzan/meta-raspberrypi/blob/master/classes/sdcard_image-rpi.bbclass as it seems to provide a class that will accomplish a similar thing. You might be able to port it to your use case (it looks like you should be able to actually).

I guess the difference is that this image addition will output a vfat each time, which if I understand your problem correctly, you said with your implementation it does not necessarily rebuild that recipe each time so the bundle and wic might drift.

[mdsketch]

I might edit that class myself to have it just output a vfat part as that's all I need from it, my partition layout is much more complex so I am using wic to get my image instead of this class.

[Hollingsworth-martin-bl]

I guess the difference is that this image addition will output a vfat each time, which if I understand your problem correctly, you said with your implementation it does not necessarily rebuild that recipe each time so the bundle and wic might drift.

Thanks for the linked class 👍

With the correct do_compile[depends] lines the vfat is rebuild correctly so that the wic and the raucb bundle don't drift apart due to (re-)build race conditions. Instead my fear is that if someone changes the content of $IMAGE_BOOT_FILES the vfat image is not automatically updated.