-
Notifications
You must be signed in to change notification settings - Fork 0
/
sketch_meeting_status.ino
138 lines (112 loc) · 3.29 KB
/
sketch_meeting_status.ino
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
#include <ESP8266WiFi.h>
#include <WiFiClient.h>
#include <ESP8266WebServer.h>
#include <ESP8266mDNS.h>
#include <FS.h>
#include "wifidata.h"
#define MEETING_PIN D7
#define MEETING_DND_PIN D1
#define MEETING_OPEN_PIN D2
#define FOCUS_PIN D6
const char* ssid = MYSSID;
const char* password = MYPASSWORD;
const char* domain = "nerd-status";
ESP8266WebServer server(80);
void setup() {
// Deactivate built in status leds. Might save some energy.
pinMode(LED_BUILTIN, OUTPUT);
digitalWrite(LED_BUILTIN, HIGH);
pinMode(D0, OUTPUT);
digitalWrite(D0, HIGH);
pinMode(MEETING_PIN, OUTPUT);
pinMode(MEETING_DND_PIN, OUTPUT);
pinMode(MEETING_OPEN_PIN, OUTPUT);
pinMode(FOCUS_PIN, OUTPUT);
setupHttpServer();
}
void loop() {
// put your main code here, to run repeatedly:
server.handleClient();
MDNS.update();
}
void setupHttpServer() {
Serial.begin(115200);
WiFi.mode(WIFI_STA);
WiFi.begin(ssid, password);
Serial.println("");
// Wait for connection
while (WiFi.status() != WL_CONNECTED) {
delay(500);
Serial.print(".");
}
Serial.println("");
Serial.print("Connected to ");
Serial.println(ssid);
Serial.print("IP address: ");
Serial.println(WiFi.localIP());
if (MDNS.begin(domain)) {
Serial.println("MDNS responder started");
}
defineRoutes();
server.onNotFound(handleNotFound);
server.begin();
Serial.println("HTTP server started");
}
void defineRoutes() {
server.on("/", handleRoot);
server.on("/meeting", []() {
setPinStatusByServerArgs(MEETING_PIN, server.arg(0));
handleRoot();
});
server.on("/meeting_dnd", []() {
setPinStatusByServerArgs(MEETING_DND_PIN, server.arg(0));
handleRoot();
});
server.on("/meeting_in", []() {
setPinStatusByServerArgs(MEETING_OPEN_PIN, server.arg(0));
handleRoot();
});
server.on("/headphones", []() {
setPinStatusByServerArgs(FOCUS_PIN, server.arg(0));
handleRoot();
});
server.on("/alloff", []() {
setPinStatusByServerArgs(MEETING_PIN, "0");
setPinStatusByServerArgs(MEETING_DND_PIN, "0");
setPinStatusByServerArgs(MEETING_OPEN_PIN, "0");
setPinStatusByServerArgs(FOCUS_PIN, "0");
handleRoot();
});
}
void setPinStatusByServerArgs(int pin, String statusArg) {
if (statusArg == "1") {
digitalWrite(pin, HIGH);
Serial.println("activating led");
} else {
digitalWrite(pin, LOW);
Serial.println("deactivating led");
}
}
// Reads the index.html from SPIFFS and sends the content
void handleRoot() {
SPIFFS.begin();
String path = "/index.html";
String dataType = "text/html";
File dataFile = SPIFFS.open(path.c_str(), "r");
String fileContent = replacePlaceholders(dataFile.readString());
server.send(200, dataType, fileContent);
dataFile.close();
}
// Replace placeholders from the html content to display LED status
String replacePlaceholders(String content) {
int readPins[] = {MEETING_PIN, MEETING_DND_PIN, MEETING_OPEN_PIN, FOCUS_PIN};
String search[] = {"[MEETING]", "[MEETING_DND]", "[MEETING_COME_IN]", "[FOCUS]"};
int i = 0;
for (int i = 0; i < 4; i++) {
content.replace(search[i], digitalRead(readPins[i]) == HIGH ? "checked=\"checked\"" : "");
}
return content;
}
void handleNotFound() {
server.send(404, "text/plain", "This is not the nerd you're looking for.");
}