-
Notifications
You must be signed in to change notification settings - Fork 0
/
geni_fine.slang
441 lines (353 loc) · 12.3 KB
/
geni_fine.slang
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
//defenv Selfie() :-
// spec("Load the principal keypair"),
// principal($1).
defenv Version() :- "set200".
defenv PolicyVersion() :- "policy200".
defenv GeniRoot() :- "w5o9SVFI94-7hYMIUFeAbwunD1pMX_agEnohn8-yBZo".
defenv MyAnchorSet() :- anchorSet().
//
// Identity set (apply to all participants)
//
defcon makeMyIdentitySet(?CN) :-
spec("Construct the identity set for self"),
{
principal($SelfKey) :- spec("identity set for $CN").
}.
defcon makeMySubjectSet() :-
spec("Construct the subject set for self"),
{
link($Self).
label("subject($Self)($Version)").
}.
defcon makeCapabilitySet(?Token, ?Scid) :-
spec("Construct a capability set for ?Scid"),
{
link($Token).
label("capability($Scid)($Version)").
}.
defcon addTokenToSubjectSet(?Token) :-
spec("Add a token to the user's subject set. Invoke after the user gets a delegation"),
{
link($Token).
label("subject($Self)($Version)").
}.
defpost updateSubjectSet(?Token) :- [addTokenToSubjectSet(?Token)].
defpost postIdSet(?CN) :- [makeMyIdentitySet(?CN)].
defpost postSubjectSet() :- [makeMySubjectSet()].
defpost passDelegation(?Token, ?Scid) :-
?CapSetRef := label($Self, "capability(?Scid)($Version)"),
[makeCapabilitySet(?Token, ?Scid), addTokenToSubjectSet(?CapSetRef)].
//
// Federation policy: trust structure and user/PI registration
//
defcon trustStructure() :-
spec("Federation trust structure: adopted by all participants"),
{
memberAuthority(?MA) :- geniRoot(?Geni), ?Geni: memberAuthority(?MA).
sliceAuthority(?SA) :- geniRoot(?Geni), ?Geni: sliceAuthority(?SA).
projectAuthority(?PA) :- geniRoot(?Geni), ?Geni: projectAuthority(?PA).
geniProxy(?GeniProxy) :- geniRoot(?Geni), ?Geni: geniProxy(?GeniProxy).
aggregate(?Agg) :- geniRoot(?Geni), ?Geni: aggregate(?Agg).
gmoc(?GeniMOC) :- geniRoot(?Geni), ?Geni: gmoc(?GeniMOC).
label("geni/trust-structure($PolicyVersion)").
}.
defcon registeredUserPolicy() :-
spec("Federation policy for registered users and PIs: adopted by all participants"),
{
geniUser(?User) :- memberAuthority(?MA), ?MA: geniUser(?User).
geniPI(?User) :- memberAuthority(?MA), ?MA: geniPI(?User).
label("geni/registered-user($PolicyVersion)").
}.
definit trustStructure(), registeredUserPolicy().
//
// Federation root: endorsements
//
defcon endorseMA(?MA) :-
spec("endorse a member authority"),
{
memberAuthority($MA) :- spec("geni endorses a member authority $MA").
label("ma/$MA($Version)").
}.
defcon endorsePA(?PA) :-
spec("endorse a project authority"),
{
projectAuthority($PA) :- spec("geni endorses a project authority $PA").
label("pa/$PA($Version)").
}.
defcon endorseSA(?SA) :-
spec("endorse a slice authority"),
{
sliceAuthority($SA) :- spec("geni endorses a slice authority $SA").
label("sa/$SA($Version)").
}.
defcon endorseCP(?CP) :-
spec("endorse an aggregate"),
{
aggregate($CP) :- spec("geni endorses an aggregate $CP").
label("aggregate/$CP($Version)").
}.
defpost postMAEndorsement(?MA) :- [endorseMA(?MA)].
defpost postPAEndorsement(?PA) :- [endorsePA(?PA)].
defpost postSAEndorsement(?SA) :- [endorseSA(?SA)].
defpost postCPEndorsement(?CP) :- [endorseCP(?CP)].
//
// MA: endorsements for registered users and PIs.
//
defcon endorsePI(?PI) :-
spec("Endorse a geni PI"),
?CapSetRef := label($Self, "capability(MA)($Version)"),
{
geniUser($PI).
geniPI($PI).
link($CapSetRef).
label("pi/$PI($Version)").
}.
defcon endorseUser(?User) :-
spec("Endorse a geni user"),
?CapSetRef := label($Self, "capability(MA)($Version)"),
{
geniUser($User).
link($CapSetRef).
label("user/$User($Version)").
}.
defpost postPIEndorsement(?PI) :- [endorsePI(?PI)].
defpost postUserEndorsement(?User) :- [endorseUser(?User)].
//
// PA: projects and their policy sets
//
defcon memberSet() :-
{
member(?User, ?Project) :-
member(?User, ?Project, _).
member(?User, ?Project, true) :-
owner(?User, ?Project).
member(?User, ?Project, ?Delegatable) :-
?Delegator: delegateMember(?User, ?Project, ?Delegatable),
member(?Delegator, ?Project, true).
memberPrivilege(?User, ?Project, instantiate, ?Delegatable) :-
member(?User, ?Project, ?Delegatable).
memberPrivilege(?User, ?Project, ?Priv, ?Delegatable) :-
delegatesMemberPrivilege(?Delegator, ?User, ?Project, ?Priv, ?Delegatable),
memberPrivilege(?Delegator, ?Project, ?Priv, true).
delegatesMember(?Delegator, User, ?Project, ?Delegatable) :-
?Delegator: delegateMember(?User, ?Project, ?Delegatable).
delegatesMemberPrivilege(?Delegator, ?User, ?Project, ?Priv, ?Delegatable) :-
?Delegator: delegateMemberPrivilege(?User, ?Project, ?Priv, ?Delegatable).
label("pa/standard-project-membership($PolicyVersion)") :-
spec("Standard project membership policy").
}.
defpost postMemberSet() :-
[memberSet()].
defcon delegateProjectMembership(?SubjectId, ?ProjectId, ?Delegatable) :-
?CapSetRef := label($Self, "capability(?ProjectId)($Version)"),
{
delegateMember($SubjectId, $ProjectId, $Delegatable).
link($CapSetRef).
label("project membership delegation $SubjectId $ProjectId($Version)").
}.
defpost postProjectMembership(?SubjectId, ?ProjectId, ?Delegatable) :-
[delegateProjectMembership(?SubjectId, ?ProjectId, ?Delegatable)].
//
// PA authZ policy for project creation.
//
defcon projectPolicySet() :-
{
approveProject(?Owner) :-
//true.
geniPI(?Owner).
label("pa/standard-project-operations($PolicyVersion)").
}.
definit projectPolicySet().
defcon createProjectSet(?SubjectId, ?ProjectId, ?ProjectMembershipRef) :-
?CapSetRef := label($Self, "capability(PA)($Version)"),
{
owner($SubjectId, $ProjectId).
project($ProjectId, standard).
link($ProjectMembershipRef).
link($CapSetRef).
label("project/$ProjectId($Version)").
}.
defpost postProjectSet(?SubjectId, ?ProjectId, ?ProjectMembershipRef) :-
[createProjectSet(?SubjectId, ?ProjectId, ?ProjectMembershipRef)].
//
// SA: slices and their policy sets
//
defcon standardSliceControlSet() :-
{
controls(?Subject, ?Slice, true) :-
owner(?Subject, ?Slice).
controls(?Subject, ?Slice, ?Delegatable) :-
delegatesControl(?Delegator, ?Subject, ?Slice, ?Delegatable),
controls(?Delegator, ?Slice, true).
controls(?Subject, ?Slice) :-
controls(?Subject, ?Slice, _).
controlPrivilege(?Subject, ?Slice, stitch, ?Delegatable) :-
controls(?Subject, ?Slice, ?Delegatable).
controlPrivilege(?Subject, ?Slice, instantiate, ?Delegatable) :-
controls(?Subject, ?Slice, ?Delegatable).
controlPrivilege(?Subject, ?Slice, ?Priv, ?Delegatable) :-
delegatesControlPrivilege(?Delegator, ?Subject, ?Slice, ?Priv, ?Delegatable),
controlPrivilege(?Delegator, ?Slice, ?Priv, true).
delegatesControl(?Delegator, ?Subject, ?Slice, ?Delegatable) :-
?Delegator: delegateControl(?Subject, ?Slice, ?Delegatable).
delegatesControlPrivilege(?Delegator, ?Subject, ?Slice, ?Priv, ?Delegatable) :-
?Delegator: delegatesControlPrivilege(?Subject, ?Slice, ?Priv, ?Delegatable).
label("sa/standard-slice-control($PolicyVersion)") :-
spec("Standard slice control policy").
}.
defpost postStandardSliceControlSet() :-
[standardSliceControlSet()].
defcon standardSliceDefaultPrivilegeSet() :-
{
controlPrivilege(?Subject, ?Slice, info, ?Delegatable) :-
slice(?Slice, ?Project, standard),
?PA := rootPrincipal(?Project),
projectAuthority(?PA),
?PA: project(?Project, standard),
?PA: memberPrivilege(?Subject, ?Project, info, ?Delegatable).
controlPrivilege(?Subject, ?Slice, stop, true) :-
slice(?Slice, ?Project, standard),
?PA := rootPrincipal(?Project),
projectAuthority(?PA),
?PA: project(?Project, standard),
?PA: owner(?Subject, ?Project).
controlPrivilege(?Subject, ?Slice, stitch, true) :-
slice(?Slice, ?Project, standard),
?PA := rootPrincipal(?Project),
projectAuthority(?PA),
?PA: project(?Project, standard),
?PA: owner(?Subject, ?Project).
controlPrivilege(?Subject, ?Slice, stitch) :-
slice(?Slice, ?Project, standard),
gmoc(?Subject).
controlPrivilege(?Subject, ?Slice, info) :-
slice(?Slice, ?Project, standard),
gmoc(?Subject).
controlPrivilege(?Subject, ?Slice, stop) :-
slice(?Slice, ?Project, standard),
gmoc(?Subject).
label("sa/standard-slice-privilege($PolicyVersion)") :-
spec("Standard slice default privilege policy").
}.
defpost postStandardSliceDefaultPrivilegeSet() :-
[standardSliceDefaultPrivilegeSet()].
defcon delegateSliceControl(?SubjectId, ?SliceId, ?Delegatable) :-
?CapSetRef := label($Self, "capability(?SliceId)($Version)"),
{
delegateControl($SubjectId, $SliceId, $Delegatable).
link($CapSetRef).
label("slice control delegation $SubjectId $SliceId($Version)").
}.
defpost postSliceControl(?SubjectId, ?SliceId, ?Delegatable) :-
[delegateSliceControl(?SubjectId, ?SliceId, ?Delegatable)].
//
// SA authZ policy for slice creation.
//
defcon slicePolicySet() :-
{
approveSlice(?Subject, ?Project) :-
?PA := rootPrincipal(?Project),
projectAuthority(?PA),
?PA: project(?Project, standard),
?PA: memberPrivilege(?Subject, ?Project, instantiate, _),
geniUser(?Subject).
label("sa/standard-slice-operations($PolicyVersion)").
}.
definit slicePolicySet().
//
// A newly approved slice is created as a set with links to its policy sets.
//
defcon createSliceSet(?SubjectId, ?SliceId, ?ProjectId, ?SliceControlRef, ?SlicePrivRef) :-
?CapSetRef := label($Self, "capability(SA)($Version)"),
{
owner($SubjectId, $SliceId).
slice($SliceId, $ProjectId, standard).
link($SliceControlRef).
link($SlicePrivRef).
link($CapSetRef).
label("slice/$SliceId($Version)").
}.
defpost postSliceSet(?SubjectId, ?SliceId, ?ProjectId, ?SliceControlRef, ?SlicePrivRef) :-
[createSliceSet(?SubjectId, ?SliceId, ?ProjectId, ?SliceControlRef, ?SlicePrivRef)].
//
// Aggregate
//
defcon aggregatePolicySet() :-
{
approveSliver(?Subject, ?Slice) :-
?SA := rootPrincipal(?Slice),
?SA: slice(?Slice, ?Project, standard),
sliceAuthority(?SA),
?SA: controlPrivilege(?Subject, ?Slice, instantiate, _),
geniUser(?Subject).
label("aggregate/standard-slice-operations($PolicyVersion)").
}.
definit aggregatePolicySet().
//
// Omitted: createSliver
// For this demo/benchmark, we"re just checking approveSliver authorizations.
// createSliver would show how to represent a sliver and its resources in trust logic. TBD.
//
//
// Guards
// There are three for primary GENI interfaces:
// pa.createProject, sa.createSlice, agg.createSliver.
// AuthZ for other agg slice operations is similar to approveSliver.
//
defguard createProject() :-
spec("Guard for ProjectAuthority.createProject"),
?PolicyRef := label("pa/standard-project-operations($PolicyVersion)"),
{
link($MyAnchorSet).
link($PolicyRef).
link($BearerRef).
approveProject($Subject)?
}.
defguard createSlice(?ProjectId) :-
spec("Guard for SliceAuthority.createSlice"),
?PolicyRef := label("sa/standard-slice-operations($PolicyVersion)"),
{
link($MyAnchorSet).
link($PolicyRef).
link($BearerRef).
approveSlice($Subject, $ProjectId)?
}.
defguard createSliver(?SliceId) :-
spec("Guard for Aggregate.createSliver"),
?PolicyRef := label("aggregate/standard-slice-operations($PolicyVersion)"),
{
link($MyAnchorSet).
link($PolicyRef).
link($BearerRef).
approveSliver($Subject, $SliceId)?
}.
//
// Local example
//
defcon fedEndorsementStub() :-
?E1 := endorseMA($Self),
?E2 := endorsePA($Self),
?E3 := endorseSA($Self),
?E4 := endorseCP($Self),
{
link($E1).
link($E2).
link($E3).
link($E4).
label("geni/endorse-self-stub($Version)").
}.
//
// Disabled the following from anchorSet()
// Caused infinite loops
// ?FedEndorseRef := fedEndorsementStub(),
// link($FedEndorseRef).
//
defcon anchorSet() :-
?FedStructureRef := label("geni/trust-structure($PolicyVersion)"),
?FedUserRef := label("geni/registered-user($PolicyVersion)"),
{
geniRoot($GeniRoot).
link($FedStructureRef).
link($FedUserRef).
label("geni/anchor-set($Version)").
}.