Migrated Build System to Gradle 8.9 and Java 17

[javadev]

This is the new Gradle script, but it currently doesn't include Checkstyle.

[fishercoder1534]

Thanks for the effort, is it possible to add any basic checkStyle as well?

[javadev]

I have example with checkstyle gradle plugin

plugins {
    id 'java'
    id 'checkstyle' // Apply the Checkstyle plugin
}

group = 'com.fishercoder'
version = '1.0-SNAPSHOT'

java {
    toolchain {
        languageVersion = JavaLanguageVersion.of(17)
    }
}

tasks.javadoc {
    options.encoding = 'UTF-8'
}

tasks.compileJava {
    options.encoding = 'UTF-8'
}

repositories {
    mavenCentral()
}

dependencies {
    implementation 'com.google.code.gson:gson:2.10.1'
    implementation 'org.apache.commons:commons-collections4:4.0'

    testImplementation 'org.junit.jupiter:junit-jupiter-api:5.10.3'
    testRuntimeOnly 'org.junit.jupiter:junit-jupiter-engine:5.10.3'

    testImplementation 'org.assertj:assertj-core:3.11.1'
    compileOnly 'org.projectlombok:lombok:1.18.32'
    annotationProcessor 'org.projectlombok:lombok:1.18.32'
    testCompileOnly 'org.projectlombok:lombok:1.18.32'
    testAnnotationProcessor 'org.projectlombok:lombok:1.18.32'
}

testing {
    suites {
        test {
            useJUnitJupiter()
        }
    }
}

tasks.withType(Test).configureEach {
    maxParallelForks = Runtime.runtime.availableProcessors()
}

// Configure Checkstyle
checkstyle {
    toolVersion = '10.12.0' // Set Checkstyle version
    config = rootProject.resources.text.fromFile('config/checkstyle/checkstyle.xml') // Path to Checkstyle configuration file
}

tasks.checkstyleMain {
    reports {
        xml.required.set(false) // Disable XML report
        html.required.set(true)  // Enable HTML report
    }
}

tasks.checkstyleTest {
    reports {
        xml.required.set(false) // Disable XML report
        html.required.set(true)  // Enable HTML report
    }
}

[javadev]

Could you please let me know which checkstyle tool version is currently being used?

[javadev]

I've added Checkstyle version 6.17.